XSLT1.0 находит неизвестные элементы в XML и помещает их в другое место
Я не уверен, что заголовок правильный. У меня есть XML-файл, который выглядит так:
XML-FILE
<main>
<mainelement attribute="on">
<basic>23</basic>
random
<stuff id="10"/>
<a>sometext</a>
<b_1>1</b_1>
<b_2>0.300000</b_2>
<d att="one"/>
<e>value</e>
</mainelement>
<otherlement>
...
</otherlement>
</main>
Я форматирую файл, чтобы соответствовать определенной норме. Все теги ae известны и желательны. но есть вероятность, что там есть и другие вещи, которые не соответствуют норме. (т.е. базовый, случайный и прочее). Я написал следующее
XSL-Script
<xsl:template match="main/mainelement">
<mainelement>
<xsl:copy-of select="a">
<xsl:variable name="b1" select="b_1"/>
<xsl:variable name="b2" select="b_2"/>
<b item1="{b1}" item2="{b2}">
<xsl:variable name="c" select="c"/>
<xsl:if test="$c">
<xsl:copy-of select="c">
</xsl:if>
<xsl:if test="not(c)">
<c>default</c>
</xsl:if>
<xsl:copy-of select="d">
<xsl:variable name="e" select="e"/>
<xsl:element name="e">
<xsl:attribute name="att">
<xsl:value-of select="$e">
</xsl:attribute>
</xsl:element>
</mainelement>
<!-- surrounds every element or text() that is unknown with the undefined-tag -->
<xsl:for-each select="* | text()">
<xsl:choose>
<xsl:when test="name()='a'"/>
<xsl:when test="name()='b_1'"/>
<xsl:when test="name()='b_2'"/>
<xsl:when test="name()='c'"/>
<xsl:when test="name()='d'"/>
<xsl:otherwise>
<undefined>
<xsl:copy-of select="current()"/>
</undefined>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each>
</xsl:template>
это делает почти то, что я хочу достичь. Проблема в том, что я не знаю, есть ли там что-то помимо нормы, и если в вышеприведенном нет ничего подобного элементарному, случайному или прочему, то вообще не должно быть тега
ВЫХОД
<main>
<mainelement attribute="on">
<a>sometext</a>
<b item1="1" item2="0.3">
<c>default</c>
<d att="one"/>
<e att="value"/>
</mainelement>
<undefined>
<basic>23</basic>
</undefined>
<undefined>
random
</undefined>
<undefined>
<stuff id="10"/>
</undefined>
<otherlement>
...
</otherlement>
</main>
но я хочу добиться этого:
Желаемый-выход
<main>
<mainelement attribute="on">
<a>sometext</a>
<b item1="1" item2="0.3">
<c>default</c>
<d att="one"/>
<e att="value"/>
</mainelement>
<undefined>
<basic>23</basic>
random
<stuff id="10"/>
</undefined>
<otherlement>
...
</otherlement>
</main>
Я думаю, я слишком много думал об этом, и поэтому я немного ослепился от простого решения, так что каждая совершенно другая попытка также ценится. Лучшее решение для метода xsl:choose тоже было бы круто, его стиль отпугивает меня... важная часть заключается в том, что я хочу исключить все, что не соответствует норме, и поместить его в другое место. Но если нет ничего, кроме нормы, ничего не должно произойти, за исключением того, что я изменил ae. Я подумал о конкатенации переменных в xsl: select и создавал выходные данные, только если вся переменная не была пустой, но это казалось невозможным в XSL1. +0,0
надеюсь, я правильно объяснил свою проблему. Большое спасибо заранее!
Рейнеке
1 ответ
Я в основном догадываюсь здесь, но, возможно, это то, что вы ищете:
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/main">
<xsl:copy>
<xsl:apply-templates select="mainelement"/>
<undefined>
<xsl:copy-of select="mainelement/node()[not(self::a or self::b_1 or self::b_2 or self::c or self::d or self::e)]"/>
</undefined>
<xsl:copy-of select="otherlement"/>
</xsl:copy>
</xsl:template>
<xsl:template match="mainelement">
<xsl:copy>
<xsl:copy-of select="@* | a"/>
<b item1="{b_1}" item2="{b_2}"/>
<xsl:copy-of select="c"/>
<xsl:if test="not(c)">
<c>default</c>
</xsl:if>
<xsl:copy-of select="d"/>
<e att="{e}"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
Применительно к вашему примеру ввода, результат:
<?xml version="1.0" encoding="UTF-8"?>
<main>
<mainelement attribute="on">
<a>sometext</a>
<b item1="1" item2="0.300000"/>
<c>default</c>
<d att="one"/>
<e att="value"/>
</mainelement>
<undefined>
<basic>23</basic>
random
<stuff id="10"/>
</undefined>
<otherlement>
...
</otherlement>
</main>
В качестве альтернативы, вы можете сделать немного более элегантно:
<xsl:template match="/main">
<xsl:copy>
<xsl:apply-templates select="mainelement"/>
<xsl:variable name="whitelist" select="mainelement/a | mainelement/b_1 | mainelement/b_2 | mainelement/c | mainelement/d | mainelement/e " />
<undefined>
<xsl:copy-of select="mainelement/node()[not(count(.|$whitelist) = count($whitelist))]"/>
</undefined>
<xsl:copy-of select="otherlement"/>
</xsl:copy>
</xsl:template>
или, если ваш процессор поддерживает функцию расширения EXSLT set:diff ():
<xsl:template match="/main">
<xsl:copy>
<xsl:apply-templates select="mainelement"/>
<xsl:variable name="whitelist" select="mainelement/a | mainelement/b_1 | mainelement/b_2 | mainelement/c | mainelement/d | mainelement/e " />
<undefined>
<xsl:copy-of select="set:difference(mainelement/node(), $whitelist)"/>
</undefined>
<xsl:copy-of select="otherlement"/>
</xsl:copy>
</xsl:template>
Редактировать:
он почти делает то, что я хочу, за исключением следующего: если в mainelement нет обозначения undefined (т.е. нет базового, случайного, прочее), то вообще не должно быть никакого тега "undefined".
Ну, тогда сначала поместите "неопределенные" узлы в переменную, затем создайте <undefined> элемент, только если есть что-то в этой переменной:
<xsl:variable name="undefined" select="mainelement/node()[not(self::a or self::b_1 or self::b_2 or self::c or self::d or self::e)]"/>
<xsl:if test="$undefined">
<undefined>
<xsl:copy-of select="$undefined"/>
</undefined>
</xsl:if>