Загрузить изображения в Imgur из Mathematica

Question

Вот вызов для всех mathematica подписчики тегов. Давайте сделаем намного удобнее вставку изображений в SO сообщение от Mathematica, создав загрузчик imgur.

Как мы можем создать функцию imgur[g_] он будет растеризовать свой аргумент (убедившись, что окончательный размер не шире ширины сообщений Stackru), преобразует его в PNG, загружает его в imgur и возвращает готовую для вставки строку MarkDown, такую ​​как ![Mathematica graphic](http://i.imgur.com/ZENa4.jpg)?

Полезные ссылки:

• Imgur API
• Пример использования POST-запроса от Mathematica в блоге WRI (публикация в Twitter) от ragfield
• Пример использования POST-запросов от Mathematica на SO (загрузка в ifile.it)

Мне не удалось адаптировать этот последний метод для загрузки изображения без предварительного экспорта в файл.

---

Внимание, используйте с осторожностью! Stackru использует отдельную установку imgur, которая хранит изображения на неопределенный срок. Если вы используете основной imgur, изображения исчезнут через 6 месяцев, если их никто не просматривает. К сожалению, по состоянию на ноябрь 2011 года, кажется, нет официального способа загружать изображения в Stackru программным способом.

---

Обновление: см. Ниже решение для прямой загрузки в Stackru.

Answer 1

Маленькая птичка только что сообщила мне о решении Mathematica этого вопроса (базовая реализация все еще использует JLink, но этот ответ скрывает весь код, связанный с Java):

imgur[expr_] := Module[
 {url, key, image, data, xml, imgurUrl},
 url = "http://api.imgur.com/2/upload";
 key = "c07bc3fb59ef878d5e23a0c4972fbb29";
 image = Fold[ExportString, expr, {"PNG", "Base64"}];
 xml = Import[url, 
  "XML", "RequestMethod" -> "POST", 
  "RequestParameters" -> {"key" -> key, "image" -> image}];
 imgurUrl = Cases[xml, XMLElement["original", {}, {string_}] :> string, 
  Infinity][[1]];
 "![Mathematica graphic](" <> imgurUrl <> ")"
]

Это только V8 и XML параметры импорта "RequestMethod" а также "RequestParameters" являются недокументированными и экспериментальными (и, следовательно, могут быть изменены).

Answer 2

Примечание: получите готовую палитру с этой функциональностью здесь.

---

Решение Arnoud вызвало у меня возбуждение и нетерпение, так что здесь есть улучшение. Я не мог бы сделать это без изучения его кода. Эта версия кажется более надежной и менее подверженной ошибкам тайм-аута, но, если честно, я вообще не знаю Java, поэтому любые улучшения приветствуются.

Самое главное: эта версия загружает в stack.imgur.com напрямую, поэтому здесь безопасно использовать Stackru, не беспокоясь о том, что загруженные изображения исчезнут через некоторое время.

Я предоставляю три функции:

• stackImage загружает выражение, экспортированное как PNG, и возвращает URL
• stackMarkdown возвращает уценку, готовую к копированию
• stackCopyMarkdown копирует уценку в буфер обмена

Следующий шаг: создайте кнопку палитры, которая делает это автоматически для выбранной графики в блокноте. Улучшения в коде очень приветствуются.

---

Needs["JLink`"]


stackImage::httperr = "Server returned respose code: `1`";
stackImage::err = "Server returner error: `1`";

stackImage[g_] :=
 Module[
  {getVal, url, client, method, data, partSource, part, entity, code, 
   response, error, result},

  (* this function attempts to parse the response fro the SO server *)
  getVal[res_, key_String] :=
   With[{k = "var " <> key <> " = "},
    StringTrim[
     First@StringCases[First@Select[res, StringMatchQ[#, k ~~ ___] &], 
       k ~~ v___ ~~ ";" :> v],
     "'"]
    ];

  data = ExportString[g, "PNG"];

  JavaBlock[
    url = "https://stackru.com/upload/image";
    client = JavaNew["org.apache.commons.httpclient.HttpClient"];
    method = JavaNew["org.apache.commons.httpclient.methods.PostMethod", url];
    partSource = JavaNew["org.apache.commons.httpclient.methods.multipart.ByteArrayPartSource", "mmagraphics.png", MakeJavaObject[data]@toCharArray[]];
    part = JavaNew["org.apache.commons.httpclient.methods.multipart.FilePart", "name", partSource];
    part@setContentType["image/png"];
    entity = JavaNew["org.apache.commons.httpclient.methods.multipart.MultipartRequestEntity", {part}, method@getParams[]];
    method@setRequestEntity[entity];
    code = client@executeMethod[method];
    response = method@getResponseBodyAsString[];
  ]

  If[code =!= 200, Message[stackImage::httperr, code]; Return[$Failed]];
  response = StringTrim /@ StringSplit[response, "\n"];

  error = getVal[response, "error"];
  result = getVal[response, "result"];
  If[StringMatchQ[result, "http*"],
   result,
   Message[stackImage::err, error]; $Failed]
  ]


stackMarkdown[g_] := "![Mathematica graphics](" <> stackImage[g] <> ")"


stackCopyMarkdown[g_] := Module[{nb, markdown},
  markdown = Check[stackMarkdown[g], $Failed];
  If[markdown =!= $Failed,
   nb = NotebookCreate[Visible -> False];
   NotebookWrite[nb, Cell[markdown, "Text"]];
   SelectionMove[nb, All, Notebook];
   FrontEndTokenExecute[nb, "Copy"];
   NotebookClose[nb];
   ]
  ]

Обновить:

Вот кнопка, которая покажет предварительный просмотр выбора и предложит загрузить (или отменить). Требуется определить предыдущие функции.

Button["Upload to SO",
 Module[{cell = NotebookRead@InputNotebook[], img},
  If[cell =!= {}, img = Rasterize[cell];
   MessageDialog[
    Column[{"Upload image to StackExchange sites?", 
      img}], {"Upload and copy MarkDown" :> stackCopyMarkdown[img], 
     "Cancel" :> Null}, WindowTitle -> "Upload to StackExchange"]]]]

К сожалению, я не могу положить кнопку в палитре (CreatePalette) потому что размеры палитры будут влиять на растеризацию. Решения этой проблемы приветствуются.

Обновление 2:

Основываясь на ответе на этот вопрос, вот рабочая кнопка палитры только для Windows:

button = Button["Upload to SO",
  Module[{sel},
   FrontEndExecute[
    FrontEndToken[FrontEnd`SelectedNotebook[], "CopySpecial", "MGF"]];
   sel = Cases[NotebookGet@ClipboardNotebook[], 
     RasterBox[data_, ___] :> 
      Image[data, "Byte", ColorSpace -> "RGB", Magnification -> 1], 
     Infinity];
   If[sel =!= {},
    With[{img = First[sel]},
     MessageDialog[
      Column[{"Upload image to StackExchange sites?", 
        img}], {"Upload and copy MarkDown" :> stackCopyMarkdown[img], 
       "Cancel" :> Null}, WindowTitle -> "Upload to StackExchange"]
     ]
    ]
   ]
  ]

CreatePalette[button]

Предупреждение: он уничтожает содержимое буфера обмена, даже если вы нажмете "Отмена" в окне предварительного просмотра.

Answer 3

Примечание: это использует анонимный загрузчик imgur с моим анонимным ключом. Сайт imgur ограничивает загрузку до 50 загрузок в час, что должно быть нормально, но это может вызвать проблемы, если многие люди пробуют это одновременно. Поэтому, пожалуйста, получите свой собственный анонимный ключ здесь:

http://imgur.com/register/api_anon

А затем замените ключ в приведенном ниже коде своим собственным ключом (спасибо!).

Самой сложной частью кода было преобразование выражения Mathematica в изображение PNG в кодировку Base64 в кодировку URL. Есть около 1000 способов сделать это неправильно, и я думаю, что мне удалось попробовать их все.

Код разбивается на несколько частей:

• Постройте почтовый URL
• Установите соединение HTTP
• Отправьте ПОЧТОВЫЙ URL
• Прочитайте результат, который является XML
• Извлеките imgur URL из XML
• Отформатируйте imgur url как уценку (или как Mathematica Hyperlink функция).

Вот код:

imgur[expr_] :=
 Module[{url, key, image, data, jUrl, jConn, jWriter, jInput, buffer,
   byte, xml, imgurUrl},
  Needs["JLink`"];
  JLink`JavaBlock[
   JLink`LoadJavaClass["java.net.URLEncoder"];
   url = "http://api.imgur.com/2/upload";
   key = "c07bc3fb59ef878d5e23a0c4972fbb29";
   image = ExportString[ExportString[expr, "PNG"], "Base64"];
   data =
    URLEncoder`encode["key"   , "UTF-8"] <> "=" <>
    URLEncoder`encode[ key    , "UTF-8"] <> "&" <>
    URLEncoder`encode["image" , "UTF-8"] <> "=" <>
    URLEncoder`encode[ image  , "UTF-8"] ;
   jUrl = JLink`JavaNew["java.net.URL", url];
   jConn = jUrl@openConnection[];
   jConn@setDoOutput[True];
   jWriter =
    JLink`JavaNew["java.io.OutputStreamWriter",
     jConn@getOutputStream[]];
   jWriter@write[data];
   jWriter@flush[];
   jInput = jConn@getInputStream[];
   buffer = {};
   While[(byte = jInput@read[]; byte >= 0), AppendTo[buffer, byte]];
   ];
  xml = ImportString[FromCharacterCode[buffer], "XML"];
  imgurUrl =
   Cases[xml,
     XMLElement["original", {}, {string_}] :>
      string, \[Infinity]][[1]];
  "![Mathematica graphic](" <> imgurUrl <> ")"
  ]

Тестирование:

In[]:= g = Graphics[{Blue, Disk[]}, PlotRange -> 1.2, ImageSize -> Small];
       pic = Overlay[{Blur[Binarize@g, 10], g}];
       imgur[pic]

Out[]= ![Mathematica graphic](http://i.imgur.com/eGOlL.png)

И фактическое изображение: