Почему навигация клавиш со стрелками не работает в TWebBrowser?

Question

Вот простая программа, которая содержит TWebBrowser управление в приложении VCL:

Unit1.pas

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, 
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.OleCtrls, SHDocVw;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  Browser: TWebBrowser;
begin
  Browser := TWebBrowser.Create(Self);
  TOleControl(Browser).Parent := Self;
  Browser.Align := alClient;
  Browser.Navigate('http://www.bbc.co.uk/');
end;

end.

Unit1.dfm

object Form1: TForm1
  Left = 0
  Top = 0
  Caption = 'Form1'
  ClientHeight = 587
  ClientWidth = 928
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'MS Sans Serif'
  Font.Style = []
  OldCreateOrder = False
  OnCreate = FormCreate
  PixelsPerInch = 96
  TextHeight = 13
end

Когда я запускаю программу, я хотел бы иметь возможность прокручивать страницу с помощью клавиш со стрелками, вверх / вниз / влево / вправо. Однако эти ключи не имеют никакого эффекта. Я могу использовать страницу вверх и страницу вниз, но не вверх / вниз / влево / вправо.

Я заново создал эквивалентное приложение в приложении.net WinForms, используя WebBrowser контроль и поведение было идентичным. Казалось бы, это наводит на мысль о проблеме с базовым контролем.

Могу ли я сделать что-нибудь, чтобы эти ключи работали? Или это просто безнадежное дело?

Answer 1

Я считаю, что форма интерпретирует эти клавиши как диалоговые клавиши навигации. Поэтому я изменил ответ элемента управления на WM_GETDLGCODE сообщение о том, что элемент управления обрабатывает эти ключи:

type
  TWebBrowser = class(SHDocVw.TWebBrowser)
  protected
    procedure WMGetDlgCode(var Msg: TWMGetDlgCode); message WM_GETDLGCODE;
  end;

procedure TWebBrowser.WMGetDlgCode(var Msg: TWMGetDlgCode);
begin
  inherited;
  Msg.Result := Msg.Result or DLGC_WANTARROWS;
end;

Это кажется, чтобы решить проблему.