Как размыть / пикселировать часть изображения, используя ImageMagick, чтобы получить большие пиксели?

Question

Я использую Perl и ImageMagick (Perl-API). На первом шаге я беру прямоугольник изображения и размываю эту часть изображения (плюс поворот этого прямоугольника). Благодаря Марку Сетчеллу это работает ниже (см. Вопрос stackru здесь: Как размыть / пикселировать часть изображения с помощью ImageMagick?).

Теперь моя цель - размыть прямоугольник этого изображения с помощью пикселей большего размера. Как я могу этого достичь?

Вот код Марка Сетчелла, который я использую до сих пор:

#!/usr/bin/perl
use strict;
use warnings;
use Image::Magick;
my $x;
my $image;
my $blurred;
my $mask;

# Create original fishscale image
$image=Image::Magick->new(size=>'600x300');
$image->Read('pattern:fishscales');
$image->Write(filename=>"1.png");

# Copy original image and blur
$blurred = $image->Clone();
$blurred->GaussianBlur('x2');
$blurred->Write(filename=>"2.png");

# Make mask and rotate
$mask=Image::Magick->new(size=>'600x300');
$mask->Read('xc:white');
$mask->Draw(fill=>'black',primitive=>'rectangle',points=>'100,100,200,200');
$mask->Set('virtual-pixel'=>'white');
$mask->Rotate(20);
$mask->Transparent('white');
$mask->Write(filename=>"3.png");

# Copy mask as alpha channel into blurred image
$blurred->Composite(image=>$mask,qw(compose CopyOpacity gravity center));

# Composite blurred image onto original
$image->Composite(image=>$blurred);
$image->Write(filename=>'result.png');

ОБНОВЛЕНИЕ: Еще одна проблема остается:

Он отлично работает с выбранным прямоугольником без вращения. Но если я применяю угол, я получаю странные результаты. Область, которая становится пикселированной, не является областью, которую я определил, но она отличается тем, что чем больше я выбираю прямоугольник от середины изображения и / или увеличиваю угол.

Посмотрите на изображения ниже с различными выбранными прямоугольниками и областями, которые становятся пикселированными. Я использовал угол 45 градусов.

Есть идеи, в чем проблема? (возможно, "составить центр тяжести CopyOpacity")

Answer 1

Что-то вроде этого?

#!/usr/bin/perl
use strict;
use warnings;
use Image::Magick;
my $x;
my $image;
my $blurred;
my $mask;

# Create original fishscale image
$image=Image::Magick->new(size=>'600x300');
$image->Read('pattern:fishscales');
$image->Write(filename=>"1.png");

# Copy original image and scale
$blurred = $image->Clone();
$blurred->Resample(x=>'100',y=>'50',filter=>'point');
$blurred->Scale(width=>'1200',height=>'600');
$blurred->Write(filename=>"2.png");

# Make mask and rotate
$mask=Image::Magick->new(size=>'600x300');
$mask->Read('xc:white');
$mask->Draw(fill=>'black',primitive=>'rectangle',points=>'20,20,220,120');
$mask->Set('virtual-pixel'=>'white');
$mask->Rotate(20);
$mask->Transparent('white');
$mask->Write(filename=>"3.png");

# Copy mask as alpha channel into blurred image
$blurred->Composite(image=>$mask,qw(compose CopyOpacity gravity center));

# Composite blurred image onto original
$image->Composite(image=>$blurred);
$image->Write(filename=>'result.png');

Answer 2

Я оставлю ответ Марка Сетчелла принятым, но опубликую свое решение для обновленного вопроса здесь. Я использую вспомогательную функцию, и я только изменил часть "Сделать маску и повернуть".

# helperfunction
sub listDraw
{
    my $image = shift;
    my $result = undef;

    for my $attrs (@_)
    {
        my ($left, $top, $width, $height, $angle) = delete @$attrs{qw(left top width height angle)};

        if ($angle - int($angle/180)*180)
        {
            my ($xm, $ym, $rad) = ($left + $width/2, $top + $height/2, $angle * PI/180);
            $attrs->{primitive} ||= 'Polygon';
            $attrs->{points} = join ' ', map {($xm + ($_->{x}-$xm)*cos($rad) + ($_->{y}-$ym)*sin($rad)) . ',' . ($ym - ($_->{x}-$xm)*sin($rad) + ($_->{y}-$ym)*cos($rad))}
                ({ x => $left, y => $top }, { x => $left + $width, y => $top }, { x => $left + $width, y => $top + $height }, { x => $left, y => $top + $height });
        }
        else
        {
            $attrs->{primitive} ||= 'Rectangle';
            $attrs->{points} ||= $left . ',' . $top . ' ' . ($left + $width - 1) . ',' . ($top + $height - 1);
        }
        last if $result = $image->Draw(%$attrs);
    }
    return $result;
}

    # Make mask and rotate
    $mask=Image::Magick->new(size=>'600x300');
    $mask->Read('xc:white');

    $mask = listDraw($mask, {
            left        => $selection_y, # y of top left corner
            top         => $selection_x, # x of top left corner
            width       => $selection_width,
            height      => $selection_height,
            angle       => 180 - $angle,
            fill        => 'black',
    });
    $mask->Set('virtual-pixel' => 'white');
    $mask->Transparent('white');