Глобальный массив Arduino не изменяется при доступе через последовательный порт?

Question

Я работаю над системой домашней автоматизации, в состав которой входит Arduino Mega2560, подключенный через USB к RaspberryPi 3 Model B. Arduino получает две короткие, простые команды через серийный номер от Pi; первая команда устанавливает "области" светодиодов, а вторая устанавливает цвета в ранее описанных областях. Синтаксис следующий для обеих команд: элементы в квадратных скобках представляют собой одиночные байты, len+off - 3 байта ascii, интерпретируемые как base-10, а r+g+b - 2 байта ascii, каждый из которых интерпретируется как шестнадцатеричный. Команда color set поддерживает переменное количество областей, как показано:

Регион Set Command

!c[regionId][stripId][len2][len1][len0][off2][off1][off0]\r

Команда цветового набора

!b[r1][r0][g1][g0][b1][b0][numRegions][regionId0]([regionId1]...)\r

Каждая команда отправляет положительные / отрицательные подтверждения, так что вы можете подумать, что я смогу сказать, что происходит, но я получаю неожиданное поведение, когда пытаюсь установить светлые цвета с помощью второй команды, несмотря на получение подтверждений, как и ожидалось. Пока что единственный разумный вывод, к которому я могу прийти, состоит в том, что для областей глобального массива изменения игнорируются и всегда остаются равными нулю. Например, этот обмен приводит к тому, что свет не горит (комментарии не находятся в реальном обмене)

Pi sends: !c00144000\r  // create regionId 0 on stripId 0; length 144 offset 0
Pi recieves: O          // positive confirmation?
Pi sends: !b00009910\r  // set regionId 0 to color 0x000099 (blue)
Pi recieves: O          // positive confirmation, but no lights?
Pi sends: !x\r          // invalid command; triggers default in switch
Pi recieves: X          // as expected, all lights turn red

Вот урезанный источник для Arduino:

#include "Arduino.h"
#include "FastLED.h"
#define WAIT while(!Serial.available()) ;; 

// Forward Declarations
const int max_strips = 2;
const int max_strip_length = 300;
const int max_leds = max_strips * max_strip_length;
CRGB leds[max_strips][max_strip_length];

const int max_regions = 20;
int regions[max_regions][3];

const int baud_rate = 9600;
unsigned char buffer[64];
unsigned char currentByte = 0;
unsigned char incommingByte;
unsigned char startChar = '!';
unsigned char endChar = '\r';
bool store = false;

// Helper Functions
void set(CRGB c) {
  for(int i = 0; i < max_strips; i++) {
      for(int j = 0; j < max_strip_length; j++) {
          leds[i][j] = c;
      }
  }
}

void set(int stripId, int length, int offset, CRGB c) {
    for(int i = offset; i < offset+length; i++) {
        leds[stripId][i] = c;
    }
}

void setup() {
  Serial.begin(baud_rate);
  for(int i = 0; i < max_strips; i++) {
      switch(i) {
          case 0: {
              FastLED.addLeds<WS2812B, 2, GRB>(leds[0], max_strip_length);
          } break;
          case 1: {
              FastLED.addLeds<WS2812B, 3, GRB>(leds[1], max_strip_length);
          } break;
      }
  }
  set(CRGB::Black);
}

void loop() {
    if(Serial.available() > 0) {
        unsigned char incomingByte = Serial.read();
        if(incomingByte == startChar) {
            currentByte = 0;
            store = true;
        }
        if(store) {
            if(incomingByte == endChar) {
                buffer[currentByte++] = incomingByte;
                store = false;
                switch(buffer[1]) {
                    case 'b': {
                        int red = (buffer[2] - '0')*16 + (buffer[3] - '0');
                        int green = (buffer[4] - '0')*16 + (buffer[5] - '0');
                        int blue = (buffer[6] - '0')*16 + (buffer[7] - '0');
                        int numRegions = buffer[8] - '0';

                        for(int i = 0; i < numRegions; i++) {
                            int regionId = buffer[9+i] - '0';

                            if(regionId >= max_regions) {
                                Serial.write('S');
                                return;
                            }

                            // Never sets anything
                            set(regions[regionId][0], regions[regionId][1], regions[regionId][2], CRGB(red, green, blue));
                        }

                        Serial.write('O');
                    } break;

                    case 'c': {
                        int regionId = buffer[2] - '0';
                        int stripId = buffer[3] - '0';
                        int length = (buffer[4] - '0')*100 + (buffer[5] - '0')*10 + (buffer[6] -'0');
                        int offset = (buffer[7] - '0')*100 + (buffer[8] - '0')*10 + (buffer[9] -'0');

                        if(regionId >= max_regions) {
                            Serial.write('R');
                            return;
                        }

                        if(stripId >= max_strips) {
                            Serial.write('S');
                            return;
                        }

                        regions[regionId][0] = stripId; // WE LOSE THESE VALUES??
                        regions[regionId][1] = length;  // ??
                        regions[regionId][2] = offset;  // ??

                        Serial.write('O');

                    } break;

                    default: {
                        set(CRGB::Red);
                        Serial.write('X');
                    } break;
                }
                currentByte = 0;
            }else if(currentByte > 64){
                store = false;
                currentByte = 0;
            } else {
                buffer[currentByte++] = incomingByte;
            }
        }
    }
    FastLED.show();
}

Буду признателен за любые советы по поводу того, что мне здесь не хватает, и в любом случае, спасибо за чтение этого места!

Answer 1

Это произошло из-за того, что у меня появилось много мусора на последовательном интерфейсе для Arduino, на котором я тестирую. Снижение скорости передачи до 2400 бит / с решает проблему на этом устройстве. Другие Arduinos в системе работают хорошо с гораздо более высокими последовательными скоростями - я подозреваю, что аппаратная проблема с кристаллом на этом конкретном Arduino, поэтому тактовые частоты не совпадают правильно между двумя сторонами последовательного соединения.