Импортировать содержимое из имен файлов, определенных в массиве

Question

Я могу объединить файлы, прочитанные import во время компиляции вот так:

enum string a = import("a.txt");
enum string b = import("b.txt");
enum string result = a ~ b;

Как я могу получить сцепленный result если у меня есть имена файлов в массиве?

enum files = ["a.txt", "b.txt"];
string result;
foreach (f; files) {
  result ~= import(f);
}

Этот код возвращается с ошибкой Error: variable f cannot be read at compile time,

Функциональный подход тоже не работает:

enum files = ["a.txt", "b.txt"];
enum result = reduce!((a, b) => a ~ import(b))("", files);

Возвращается с той же ошибкой: Error: variable b cannot be read at compile time

Answer 1

Я нашел решение, которое не использует строковые миксины:

string getit(string[] a)() if (a.length > 0) {
    return import(a[0]) ~ getit!(a[1..$]);
}

string getit(string[] a)() if (a.length == 0) {
    return "";
}

enum files = ["a.txt", "b.txt"];
enum result = getit!files;

Answer 2

Может быть, используя строковые миксины?

enum files  = ["test1", "test2", "test3"];

// There may be a better trick than passing the variable name here
string importer(string[] files, string bufferName) {
    string result = "static immutable " ~ bufferName ~ " = ";

    foreach (file ; files[0..$-1])
        result ~= "import(\"" ~ file ~ "\") ~ ";
    result ~= "import(\"" ~ files[$-1] ~ "\");";

    return result;
}

pragma(msg, importer(files, "result"));
// static immutable result = import("test1") ~ import("test2") ~ import("test3");

mixin(importer(files, "result"));
pragma(msg, result)

Answer 3

@ Тамас ответ.

Технически это можно заключить в одну функцию, используя static if который на мой взгляд выглядит чище.

string getit(string[] a)() {
    static if (a.length > 0) {
        return import(a[0]) ~ getit!(a[1..$]);
    }
    else {
        return "";
    }
}

Также технически

static if (a.length > 0)

может быть

static if (a.length)

Вы также можете учитывать неинициализированные массивы, как это

string getit(string[] a)() {
    static if (a && a.length) {
        return import(a[0]) ~ getit!(a[1..$]);
    }
    else {
        return "";
    }
}

Использование все равно будет таким же.

enum files = ["a.txt", "b.txt"];
enum result = getit!files;