SAS, программный экспорт объектов метаданных spks

Question

В SAS у меня есть структура папок, которая содержит большое количество метаданных таблицы SAS.

Для перехода из одной среды в другую нам нужно вручную создать большое количество spks и отправить их в Git. Это проблематично, потому что (а) требуется время, (б) разработчики заинтересованы в том, чтобы упаковать большое количество объектов метаданных в один файл.spk, что создает проблемы в дальнейшем, когда нужно редактировать только один из этих объектов, и ни один не может быть рассмотрены.

Есть:

1. Способ программно экспортировать файл.spk?
2. Способ проанализировать структуру папок и создать один файл spk для каждого объекта метаданных?

Было бы здорово, если бы вы указали мне полезные документы SAS или указали верное направление.

Answer 1

В вашем подходе есть две вещи, на которые следует обратить внимание:

1. Один и тот же элемент метаданных будет иметь разные контрольные суммы при двойном экспорте из-за встроенных временных меток. Это всегда будет создавать различия в GIT.
2. Экспорт каждого элемента метаданных по отдельности займет много времени - процедура ExportPackage не такая быстрая.

Но в любом случае, конечно, то, что вы предлагаете, может быть сделано! Я только что проверил ниже, и он отлично работает. Если вы не в Windows, возможно, вам придется скорректировать путь к ExportPackage утилита в канале (с помощью точки с запятой -; - для цепочки команд)..

%macro exporter(root=%sysfunc(pathname(work)) /* physical root */
    ,host=dev-meta.ACME.int /* metadata server */
    ,port=8561              /* metadata port */
    ,user=sasdemo           /* user with metadata credentials */
    ,pass=Mars123           /* password */
  );
options noquotelenmax;

data paths (keep=tree_path uri treetype);
  length tree_path $500 uri tree_uri parent_uri 
    parent_name TreeType PublicType $256;
  n=1;
  do while(metadata_getnobj("omsobj:Tree?@PublicType = 'Folder'",n,uri)>0);
  /* code for getting the metadata path */
    rc=metadata_getattr(uri,"Name",tree_path);
    rc=metadata_getattr(uri,"TreeType",TreeType);
    rc=metadata_getattr(uri,"PublicType",PublicType);
    tree_uri=uri;
    do while (metadata_getnasn(tree_uri,"ParentTree",1,parent_uri)>0);
      rc=metadata_getattr(parent_uri,"Name",parent_name);
      tree_path=strip(parent_name)||'/'||strip(tree_path);
      tree_uri=parent_uri;
    end;
    tree_path='/'||strip(tree_path);
    call symputx(cats('path',n),tree_path,'l');
    call symputx(cats('uri',n),uri,'l');
    call symputx('n',n,'l');
    output;
    n+1;
    if n>3 then leave;  /* remove this unless testing */
  end;
run;
proc sort; by tree_path;run;

/* get location of BatchExport metadata tool */
/*http://support.sas.com/documentation/cdl/en/bisag/64088
     /HTML/default/viewer.htm#a003261084.htm*/
data _null_;
   h="%sysget(SASROOT)";
   h2=substr(h,1,index(h,"SASFoundation")-2);
   call symputx("platform_object_path"
    ,cats(h2,"/SASPlatformObjectFramework/&sysver"));
run;
%put Batch tool located at: &platform_object_path;

%let connx_string= -host &host -port &port -user &user -password &pass;

%do x=1 %to &n;
  data out&x (drop=n rc);
    length uri objuri Name PublicType path $256;
    retain path "&&path&x";
    retain uri "&&uri&x";
    n=1;
    do while (metadata_getnasn(uri,'Members',n,objuri)>0);
      rc=metadata_getattr(objuri,"Name",Name);
      rc=metadata_getattr(objuri,"PublicType",PublicType);
      call symputx(cats('objuri',n),objuri,'l');
      call symputx(cats('objName',n),Name,'l');
      call symputx(cats('objType',n),PublicType,'l');
      output;
      n+1;
    end;
  run;
  proc sql noprint;
  select count(*) into: nobs from &syslast;
  %if &nobs=0 %then %do;
    drop table &syslast;
  %end;
  %else %do objn=1 %to &nobs;
    data _null_;
      infile "C: & cd ""&platform_object_path"" %trim(
        ) & ExportPackage &connx_string %trim(
        )-package ""&root&&path&x\&&objType&objn.._&&objname&objn...spk"" %trim(
        )-objects ""&&path&x/&&objname&objn(&&objType&objn)"" %trim(
        )-log ""&root&&path&x\&&objType&objn.._&&objname&objn...log"" 2>&1" 
        pipe lrecl=1000;
      input; 
      list;
    run;
  %end;
%end;
%mend;

%exporter()