Регулярное выражение XSL v1 - поиск шаблонов в тексте - IBM Watson explorer WEX
Лучший
Я пытаюсь создать сценарий XSL, который может получить следующие строки обратно, [в текст (если это происходит в этом тексте) ]:
Шаблон, который мне в основном нужен, это 3.2.14P5879 или 14.1.1Z5526.
Таким образом: Цифры Точка Цифры Точка Цифра Буква-P_or_Z Цифры
например, если у меня есть текст:
Возникла проблема с проектом 3.2.14P5879, касающаяся документа 14.1.1Z5526-ABC.docx, в котором говорится, что мы должны использовать документы "14.1.1P5526 - xyz.pdf".
Тогда было бы удивительно, если бы я мог получить следующий результат:
- <content name="test">3.2.14P5879</content>
- <content name="test">14.1.1Z5526</content>
- <content name="test">14.1.1P5526</content>
То, что я сделал до сих пор, и не работает, проверяет, соответствуют ли некоторые позиции словарному запасу. (код работает) Но результат неправильный. Он будет проверять только утверждение в начале текста.
<xsl:variable name="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'" />
<xsl:variable name="vLower" select="'abcdefghijklmnopqrstuvwxyz'" />
<xsl:variable name="vAlpha" select="concat($vUpper, $vLower)" />
<xsl:variable name="vDigits" select="'0123456789'" />
<xsl:variable name="vDot" select="'.'" />
<xsl:variable name="vProject" select="'PZ'" />
<xsl:template match="/">
<document>
<xsl:for-each select="//*[text()]">
<content name="Lengte" length="{string-length(.)}">
<xsl:value-of select="." />
</content>
<xsl:choose>
<xsl:when
test="string-length(translate(substring(., 1, 2), $vDigits, '')) = 0 and string-length(translate(substring(., 3, 1), $vDot, '')) = 0 and string-length(translate(substring(., 5, 1), $vDot, '')) = 0 and string-length(translate(substring(., 6, 2), $vDigits, '')) = 0 and string-length(translate(substring(., 8, 1), $vProject, '')) = 0 and string-length(translate(substring(., 9, 4), $vDigits, '')) = 0"
>
<content name="A" Proj-name="{.}" Proj="{substring(., 1, 11)}">
<xsl:value-of select="substring(., 1, 2)" />
</content>
<content name="B" Proj-name="{.}" Proj="{substring(., 1, 11)}">
<xsl:value-of select="substring(., 4, 1)" />
</content>
<content name="C" Proj-name="{.}" Proj="{substring(., 1, 11)}">
<xsl:value-of select="substring(., 6, 2)" />
</content>
<content name="D" Proj-name="{.}" Proj="{substring(., 1, 11)}">
<xsl:value-of select="substring(., 9, 4)" />
</content>
<content name="E" Proj-name="{.}" Proj="{substring(., 1, 11)}">
<xsl:value-of select="substring(., 1, 7)" />
</content>
<content name="F" Proj-name="{.}" Proj="{substring(., 1, 10)}">
<xsl:value-of select="." />
</content>
</xsl:when>
<xsl:when
test="string-length(translate(substring(., 1, 1), $vDigits, '')) = 0 and string-length(translate(substring(., 2, 1), $vDot, '')) = 0 and string-length(translate(substring(., 4, 1), $vDot, '')) = 0 and string-length(translate(substring(., 5, 2), $vDigits, '')) = 0 and string-length(translate(substring(., 7, 1), $vProject, '')) = 0 and string-length(translate(substring(., 8, 4), $vDigits, '')) = 0"
>
<content name="A" Proj-name="{.}" Proj="{substring(., 1, 10)}">
<xsl:value-of select="substring(., 1, 1)" />
</content>
<content name="B" Proj-name="{.}" Proj="{substring(., 1, 10)}">
<xsl:value-of select="substring(., 3, 1)" />
</content>
<content name="C" Proj-name="{.}" Proj="{substring(., 1, 10)}">
<xsl:value-of select="substring(., 5, 2)" />
</content>
<content name="D" Proj-name="{.}" Proj="{substring(., 1, 10)}">
<xsl:value-of select="substring(., 2, 4)" />
</content>
<content name="E" Proj-name="{.}" Proj="{substring(., 1, 10)}">
<xsl:value-of select="substring(., 1, 7)" />
</content>
<content name="F" Proj-name="{.}" Proj="{substring(., 1, 10)}">
<xsl:value-of select="." />
</content>
</xsl:when>
</xsl:choose>
</xsl:for-each>
</document>
</xsl:template>
Зачем мне это нужно? и ПОЧЕМУ XSL версии 1.0??? На данный момент я работаю с Watson Explorer 11.0.2 и должен получить пользовательские метаданные, к которым я могу получить доступ через действие html-xsl (custom-converter)(Regex - regex-text perl-regex perl-regex-text также доступны, но я не имею ни малейшего понятия, как их использовать (СПАСИБО, IBM за идеальную документацию)
Таким образом, чтобы быть кратким, если кто-то, кто может помочь мне получить "коды" через Regex в watson explorer - пользовательский конвертер - action (я знаю reg-выражение) -
Мне нужна помощь, чтобы получить коды обратно из текста через XSL версии 1.0
(PS, Watson explorer - поисковая система для предприятий, веб-скребок / сканер)
1 ответ
Вот пример использования функций расширения регулярных выражений EXSLT (как реализовано в libxslt). Я подозреваю, что функции расширения регулярных выражений, которые являются частью Watson Explorer, имеют такое же поведение.
XML
<root>
<item>There was an issue with project 1.2.34P5678, regarding to document 23.4.5Z6789-ABC.docx it says that we've to use the documents of "35.66.78P999 - xyz.pdf"</item>
</root>
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:regexp="http://exslt.org/regular-expressions"
extension-element-prefixes="regexp">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:template match="/root">
<output>
<xsl:for-each select="item">
<xsl:call-template name="extract-matches">
<xsl:with-param name="text" select="."/>
</xsl:call-template>
</xsl:for-each>
</output>
</xsl:template>
<xsl:template name="extract-matches">
<xsl:param name="text"/>
<xsl:param name="regex" select="'\d+\.\d+\.\d+[PZ]\d+'"/>
<xsl:if test="regexp:test($text, $regex)">
<xsl:variable name="matching-substring" select="regexp:match($text, $regex)" />
<match>
<xsl:value-of select="$matching-substring" />
</match>
<!-- recursive call -->
<xsl:call-template name="extract-matches">
<xsl:with-param name="text" select="substring-after($text, $matching-substring)"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
Результат
<?xml version="1.0" encoding="UTF-8"?>
<output>
<match>1.2.34P5678</match>
<match>23.4.5Z6789</match>
<match>35.66.78P999</match>
</output>