Как использовать XSLT для создания разных значений

Question

У меня есть XML, как это:

<items>
  <item>
    <products>
      <product>laptop</product>
      <product>charger</product>
    </products>
  </item>
  <item>
    <products>
      <product>laptop</product>
      <product>headphones</product>  
    </products>  
  </item>
</items>

Я хочу, чтобы это выглядело как

портативный компьютер
зарядное устройство
наушники

Я пытался использовать distinct-values() но я думаю, что я делаю что-то не так. Может кто-нибудь сказать мне, как добиться этого с помощью distinct-values()? Благодарю.

<xsl:template match="/">            
  <xsl:for-each select="//products/product/text()">
    <li>
      <xsl:value-of select="distinct-values(.)"/>
    </li>               
  </xsl:for-each>
</xsl:template>

но это дает мне вывод, как это:

<li>laptop</li>
<li>charger</li>
<li>laptop></li>
<li>headphones</li>

Answer 1

Решение XSLT 1.0, которое использует key и generate-id() Функция для получения различных значений:

<?xml version="1.0" encoding="UTF-8"?>
  <xsl:stylesheet
   version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" encoding="UTF-8" indent="yes"/>

<xsl:key name="product" match="/items/item/products/product/text()" use="." />

<xsl:template match="/">

  <xsl:for-each select="/items/item/products/product/text()[generate-id()
                                       = generate-id(key('product',.)[1])]">
    <li>
      <xsl:value-of select="."/>
    </li>
  </xsl:for-each>

</xsl:template>

</xsl:stylesheet>

Answer 2

Вот решение XSLT 1.0, которое я использовал в прошлом, я думаю, что оно более лаконично (и читабельно), чем использование generate-id() функция.

  <xsl:template match="/">           
    <ul> 
      <xsl:for-each select="//products/product[not(.=preceding::*)]">
        <li>
          <xsl:value-of select="."/>
        </li>   
      </xsl:for-each>            
    </ul>
  </xsl:template>

Возвращает:

<ul xmlns="http://www.w3.org/1999/xhtml">
  <li>laptop</li>
  <li>charger</li>
  <li>headphones</li>
</ul>

Answer 3

Вам не нужен "output (Different-values)", а "for-each (Different-values)":

<xsl:template match="/">              
  <xsl:for-each select="distinct-values(/items/item/products/product/text())">
    <li>
      <xsl:value-of select="."/>
    </li>
  </xsl:for-each>
</xsl:template>

Answer 4

Я пришел к этой проблеме, работая с рендерингом Sitecore XSL. И подход, который использовал key(), и подход, который использовал предыдущую ось, выполнялись очень медленно. В итоге я использовал метод, аналогичный key(), но для этого не требовалось использовать key(). Работает очень быстро.

<xsl:variable name="prods" select="items/item/products/product" />
<xsl:for-each select="$prods">
  <xsl:if test="generate-id() = generate-id($prods[. = current()][1])">
    <xsl:value-of select="." />
    <br />
  </xsl:if>
</xsl:for-each>

Answer 5

distinct-values(//product/text())

Answer 6

Я обнаружил, что вы можете делать то, что вы хотите с XSLT 1.0 без generate-id() а также key() функции.

Вот специфичное для Microsoft решение (класс.NET XslCompiledTransform, или MSXSLT.exe или Microsoft platfocm COM-объекты).

Это основано на этом ответе. Вы можете скопировать отсортированный узел в переменную ($sorted-products в таблице стилей ниже), затем преобразуйте ее в набор узлов, используя ms:node-set функция. Тогда вы сможете for-each второй раз после сортировки набора узлов:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:ms="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="ms">

  <xsl:output method="html" indent="yes" />

  <xsl:template match="/">
    <xsl:variable name="sorted-products">
        <xsl:for-each select="//products/product">
            <xsl:sort select="text()" />

            <xsl:copy-of select=".|@*" />
        </xsl:for-each>
    </xsl:variable>

    <xsl:variable name="products" select="ms:node-set($sorted-products)/product" />

    <xsl:for-each select="$products">
      <xsl:variable name='previous-position' select="position()-1" />

      <xsl:if test="normalize-space($products[$previous-position]) != normalize-space(./text())">
        <li>
          <xsl:value-of select="./text()" />
        </li>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

выход:

<li>charger</li>
<li>headphones</li>
<li>laptop</li>

Вы можете попробовать это на онлайн-площадке.