Как сделать функцию многократного использования для Flex Datagrid?

Question

У меня есть функция метки, как:

private function formatDate (item:Object, column:DataGridColumn):String
{
    var df:DateFormatter = new DateFormatter();
    df.formatString = "MM/DD/YY";

    if (column.dataField == "startDate") {
        return df.format(item.startDate);
    }

    return "ERR";
}

Который я использую в столбце данных, используя labelFunction,

Это прекрасно работает, если мое поле данных называется startDate. Я хочу сделать эту функцию общей, чтобы я мог использовать ее везде.

Как я могу это сделать. я думаю, что мне нужно использовать какое-то "отражение" - или, возможно, вообще другой подход?

Answer 1

Вы можете определить другую функцию, давайте назовем ее partial это связывает некоторые дополнительные аргументы с вашей функцией:

function partial( func : Function, ...boundArgs ) : Function {
  return function( ...dynamicArgs ) : * {
    return func.apply(null, boundArgs.concat(dynamicArgs))
  }
}

Затем вы меняете свою функцию следующим образом:

private function formatDate( dataField : String, item : Object, column : DataGridColumn ) : String {
  var df : DateFormatter = new DateFormatter();

  df.formatString = "MM/DD/YY";

  if ( column.dataField == dataField ) {
    return df.format(item[dataField]);
  }

  return "ERR";
}

Обратите внимание, что я добавил новый аргумент под названием dataField сначала в списке аргументов, и заменил все ссылки на "startDate" с этим аргументом.

И используйте это так:

var startDateLabelFunction : Function = partial(formatDate, "startDate");
var endDateLabelFunction   : Function = partial(formatDate, "endDate");

partial Функция возвращает новую функцию, которая вызывает исходную функцию с параметрами от вызова до частичного сцепления с параметрами новой функции... Вы со мной? Другой способ выразить это в том, что он может возвращать новую функцию, где N аргументов предварительно связаны с конкретными значениями.

Давайте пройдемся по шагам:

partial(formatDate, "startDate") возвращает функцию, которая выглядит следующим образом:

function( ...dynamicArgs ) : * {
  return func.apply(null, boundArgs.concat(dynamicArgs));
}

но func а также boundArgs это то, что вы передали в качестве аргументов partialтак что можно сказать, что это выглядит так:

function( ...dynamicArgs ) : * {
  return formatDate.apply(null, ["startDate"].concat(dynamicArgs));
}

который, когда он вызывается, будет более или менее таким же, как этот

function( item : Object, column : DataGridColumn ) : * {
  return formatDate("startDate", item, column);
}

Тада!

Answer 2

Вы можете сделать функцию универсальной, используя атрибут dataField столбца в качестве ключа вашего элемента.

private function formatDate (item:Object, column:DataGridColumn):String
{
    var df:DateFormatter = new DateFormatter();
    df.formatString = "MM/DD/YY";

    var value:object = item[column.dataField];

    return df.format(value);
}

-Бен

Answer 3

Вот более общий способ:

public static function getDateLabelFunction(dateFormatString:String=null, mxFunction:Boolean = false) : Function {
        var retf:Function;

        // defaults
        if(dateFormatString == null) dateFormatString = "MM/DD/YY";
        if(mxFunction) {
            retf = function  (item:Object, column:DataGridColumn):String
            {
                var df:DateFormatter = new DateFormatter();
                df.formatString = dateFormatString;

                var value:Object = item[column.dataField];

                return df.format(value);
            }
        }else {
            retf = function  (item:Object, column:GridColumn):String
            {
                var df:DateFormatter = new DateFormatter();
                df.formatString = dateFormatString;

                var value:Object = item[column.dataField];

                return df.format(new Date(value));
            }
        }

        return retf;

    }

Использование (Spark DataGrid)

var labelFunction = getDateLabelFunction();

или для MX Datagrid

var labelFunction = getDateLabelFunction(null,true);

передать пользовательскую строку формата даты:

var labelFunction = getDateLabelFunction("DD/MM/YYYY",true);

По умолчанию используется значение "ММ / ДД / ГГГГ";