Perl select return error "неверный дескриптор файла"

Question

Я пытаюсь реализовать межпроцессное взаимодействие с использованием каналов и select команда. Вот первая попытка:

use warnings;
use strict;
use feature qw(say);
use IO::Select;
use IO::Handle;

my @rh;
my %childs;
my $numChilds=2;
$SIG{CHLD}='IGNORE'; #Reap childs automatically

for my $i (1..$numChilds) {
  pipe(my $pread, my $pwrite);
  push(@rh,$pread);
  $pwrite->autoflush(1);
  my $child = fork();
  if ($child==0) {
    runChild($i,$pwrite);
  }
  $childs{$pread->fileno()}={pid=>$child,id=>$i,i=>0};
}

my $sel = IO::Select->new( @rh );
while (1) {
  say "Running select..";
  my @ready = $sel->can_read;
  last if (! @ready);
  for my $fh (@ready) {
    say "Processing file descriptor ".($fh->fileno());
    chomp(my $line=<$fh>);
    my $fd=$fh->fileno();
    my $child=$childs{$fd}->{id};
    say "Got line: \"$line\"..";
    my $nmsg=($childs{$fd}->{i})+1;
    if ($nmsg==2) {
      $fh->close();
      $sel->remove($fh);
      say "Select count: ".($sel->count());
      say "Closed fh $child..";
    } else {
      $childs{$fd}->{i}=$nmsg;
    }
  }
}
say "Done.";

sub someSeconds { return int(rand(4))+3; }

sub runChild {
  my ($i, $pipe)=@_;

  sleep (someSeconds());
  print $pipe "Child $i says: A\n";
  sleep (someSeconds());
  print $pipe "Child $i says: B\n";
  exit 0;
}

Выход:

Running select..
Processing file descriptor 4
Got line: "Child 2 says: A"..
Running select..
Processing file descriptor 3
Got line: "Child 1 says: A"..
Running select..
Processing file descriptor 4
Got line: "Child 2 says: B"..
Select count: 1
Closed fh 2..
Running select..
Done.

Проблема в том, что последнее сообщение от ребенка 1 отсутствует Got line: "Child 1 says: B",

я бегу strace prog.pl который дал:

select(8, [3 4], NULL, NULL, NULL)      = -1 EBADF (Bad file descriptor)

на последнем select вызов..

Answer 1

  $fh->close();
  $sel->remove($fh);

Вы должны сначала удалить дескриптор файла из выбора, а затем закрыть его. Как только он закрыт, он больше не действителен (то есть fileno($fh) вернет undef) и не может быть удален. И если невозможно удалить, select все равно попытается выбрать этот (недопустимый) дескриптор файла, вызывая EBADF.