Как использовать yy_scan_string в lex

Question

Я хочу разобрать строку, которую я даю парсеру в основной функции yacc . Я знаю, что это можно сделать с помощью yy_scan_string но я не знаю, как его использовать. Я искал в Интернете и на страницах руководства, но мне все еще не ясно. Пожалуйста, помогите мне.

Answer 1

В случае, если кому-то нужен образец для лексера с реентрантом:

int main(void)
{
    yyscan_t scanner;
    YY_BUFFER_STATE buf;
    yylex_init(&scanner);
    buf = yy_scan_string("replace me with the string youd like to scan", scanner);
    yylex(scanner);
    yy_delete_buffer(buf, scanner);
    yylex_destroy(scanner);
    return 0;
}

Answer 2

Это работает для меня. У меня есть этот код в разделе подпрограмм (то есть в третьем разделе) моего файла Bison:

struct eq_tree_node *parse_equation(char *str_input)
{
    struct eq_tree_node *result;

    yy_scan_string(str_input);
    yyparse();
    /* to avoid leakage */
    yylex_destroy();

    /* disregard this. it is the function that I defined to get
    the result of the parsing. */
    result = symtab_get_parse_result();

    return result;
}

Answer 3

Я всегда рекомендую эту страницу людям, которые хотят изучать lex/yacc (или flex/bison)

Answer 4

Это сработало для меня... используйте yy_scan_string()

int main(int argc, char **argv)
{
char Command[509];
int ReturnVal;

    char input[40] = "This is my input string";

    /*Copy string into new buffer and Switch buffers*/
    yy_scan_string (input);

    /*Analyze the string*/
    yylex();

    /*Delete the new buffer*/
    yy_delete_buffer(YY_CURRENT_BUFFER);
}

Answer 5

Здесь уже есть несколько хороших ответов. Но для моих целей мне нужно было неоднократно переключаться между строковыми буферами, которые нужно было проанализировать. Проблема здесь в том, что flex нужно очищать после каждого запуска обработки и сбрасывать свои внутренние разборщики/счетчики/и т.д. На момент написания ни один из существующих ответов не демонстрирует это.

По сути, это означает сохранение YY_BUFFER_STATE yy_buffer_state;где-то рядом и звонит yy_delete_buffer( yy_buffer_state )когда пришло время переключаться между строками. Когда flex назначается новая строка для сканирования (с yy_scan_string()), создается новый YY_BUFFER_STATE, который вам нужно отслеживать.

Я попытался показать достаточно полный пример, но setLexerBuffer()ближе к низу ~

Например:

      %{
#include "flex_tokens_and_yylval.h"

extern LexYYLVal yylval;                    // my custom yylval
extern YY_BUFFER_STATE yy_buffer_state;
%}

digit             [0-9]
letter            [a-zA-Z]
udderscore        "_"
sign              [+-]
period            "."

real              {sign}?({digit}*{period}{digit}+)
int               {sign}?{digit}+
identifier        ({letter}|{udderscore})+({letter}|{digit}|{udderscore})*
/* [...]  rest of the scanner rules */

%%

<<EOF>>             { return LEX_EOF; }
{real}              {
                        yylval.data.val_real = strtod( yytext, NULL ); 
                        return LEX_REAL;
                    }

{int}               {
                        yylval.data.val_integer = strtol( yytext, NULL, 10 );
                        return LEX_INTEGER;
                    }
{identifier}        {
                        strncpy( yylval.data.val_string, yytext, MAX_IDENTIFIER_LENGTH );
                        yylval.data.val_string[MAX_IDENTIFIER_LENGTH-1]='\0';
                        return LEX_IDENTIFIER;
                    }
[ \t\n\r]           { /* skip whitespace */ }
/* [...]  rest the scanner outputs */

%%

// NOT THREAD SAFE, DON'T USE FROM MULTIPLE THREADS
LexYYLVal yylval;
int yy_first_ever_run = 1;
char LexEmptyBuffer[3] = { '\n', '\0', '\0' };
YY_BUFFER_STATE yy_buffer_state;

/*
 * Point flex at a new string to process, resetting
 * any old results from a previous parse.
 */
void setLexerBuffer( const char *expression_string )
{
    /* out with the old (If any? How does flex know?) */
    if ( !yy_first_ever_run )
    {
        // This doesn't cause any issues (according to valgrind)
        // but I also don't see any reason to call it before the
        // first lex-run.
        yy_delete_buffer( yy_buffer_state );
    }
    else
    {
        yy_first_ever_run = 0;
    }

    /* just make sure we're pointing at something */
    if ( expression_string == NULL )
    {
        expression_string = LexEmptyBuffer;
    }

    /* reset the scan */    
    yy_buffer_state = yy_scan_string( expression_string );  /* auto-resets lexer state */
}

Итак, это позволяет вам запустить цикл управления, например:

      int main( void )
{
    LexResultToken token;

    setLexerBuffer( "12.3 * 0.96" );
    do
    {
        token = yylex();
        printToken( token );
    }
    while( token != LEX_EOF );

    setLexerBuffer( "( A + B ) < ( C * D )" );
    do
    {
        token = yylex();
        printToken( token );
    }
    while( token != LEX_EOF );

    yylex_destroy();

    return 0;
}

Этот пример был запущен через valgrind для проверки корректности памяти.

Answer 6

Я нашел и пример здесь для себя. Пусть это может быть полезно для вас:

http://osdir.com/ml/lex.flex.windows/2003-04/msg00008.html