Flex: как определить, заблокировал ли пользователь общий доступ к записи

Question

Простой вопрос: как мне определить в ActionScript, если пользователь заблокировал запись данных в общий объект?

sharedObj = SharedObject.getLocal("rememberme");

Этот возврат всегда разделяемый объект, но его размер равен 0, даже если я заблокировал общий объект.

Когда я пытаюсь сохранить данные в общий объект и очистить его, выдается ошибка, потому что запись заблокирована. Так что будет правильным способом проверить, отключена ли запись в общий объект?

Error: Error #2130: Unable to flush SharedObject.

Answer 1

var my_so:SharedObject = SharedObject.getLocal("mySpace");
var flushStatus:String = null;
try {
    flushStatus = my_so.flush();
} catch (error:Error) {
    trace("Error...Could not write SharedObject to disk\n");
}
if (flushStatus != null) {
    switch (flushStatus) {
        case SharedObjectFlushStatus.PENDING :
            trace("Requesting permission to save object...\n");
            my_so.addEventListener(NetStatusEvent.NET_STATUS, onFlushStatus);
            break;
        case SharedObjectFlushStatus.FLUSHED :
            trace("Value flushed to disk.\n");
            break;
    }
}
function onFlushStatus(event:NetStatusEvent):void {
    trace("User closed permission dialog...\n");
    switch (event.info.code) {
        case "SharedObject.Flush.Success" :
            trace("User granted permission -- value saved.\n");
            break;
        case "SharedObject.Flush.Failed" :
            trace("User denied permission -- value not saved.\n");
            break;
    }
my_so.removeEventListener(NetStatusEvent.NET_STATUS, onFlushStatus);
}

Если общий объект заблокирован, вы можете catch сообщение об ошибке еще, если 0 идет к SharedObjectFlushStatus.PENDING,

ИСТОЧНИК