В Clojure 1.3, Как читать и писать файл

Question

Я хотел бы знать "рекомендуемый" способ чтения и записи файла в clojure 1.3 .

1. Как прочитать весь файл
2. Как читать файл построчно
3. Как написать новый файл
4. Как добавить строку в существующий файл

Answer 1

Предполагая, что мы делаем только текстовые файлы, а не какие-то сумасшедшие бинарные вещи.

Номер 1: как прочитать весь файл в память.

(slurp "/tmp/test.txt")

Не рекомендуется, когда это действительно большой файл.

Номер 2: как читать файл построчно.

(use 'clojure.java.io)
(with-open [rdr (reader "/tmp/test.txt")]
  (doseq [line (line-seq rdr)]
    (println line)))

with-open макрос заботится о том, чтобы читатель был закрыт в конце тела. Функция чтения приводит строку (она также может сделать URL и т. Д.) В BufferedReader, line-seq поставляет ленивый seq. Требование следующего элемента ленивого seq приводит к строке, читаемой читателем.

Обратите внимание, что начиная с Clojure 1.7, вы также можете использовать преобразователи для чтения текстовых файлов.

Номер 3: как записать в новый файл.

(use 'clojure.java.io)
(with-open [wrtr (writer "/tmp/test.txt")]
  (.write wrtr "Line to be written"))

Снова, with-open заботится о том, чтобы BufferedWriter закрыто в конце тела. Писатель заставляет строку в BufferedWriter, который вы используете использовать через Java-взаимодействия: (.write wrtr "something").

Вы также можете использовать spit, противоположно slurp:

(spit "/tmp/test.txt" "Line to be written")

Номер 4: добавить строку в существующий файл.

(use 'clojure.java.io)
(with-open [wrtr (writer "/tmp/test.txt" :append true)]
  (.write wrtr "Line to be appended"))

То же, что и выше, но теперь с опцией добавления.

Или снова с spit, противоположно slurp:

(spit "/tmp/test.txt" "Line to be written" :append true)

PS: Чтобы быть более точным в том, что вы читаете и записываете в файл, а не что-то еще, вы можете сначала создать объект File, а затем привести его к BufferedReader или писатель:

(reader (file "/tmp/test.txt"))
;; or
(writer (file "tmp/test.txt"))

Файловая функция также находится в clojure.java.io.

PS2: Иногда удобно видеть, что является текущим каталогом (поэтому "."). Вы можете получить абсолютный путь двумя способами:

(System/getProperty "user.dir") 

или же

(-> (java.io.File. ".") .getAbsolutePath)

Answer 2

Если файл помещается в память, вы можете прочитать и записать его с помощью slurp и spit:

(def s (slurp "filename.txt"))

(s теперь содержит содержимое файла в виде строки)

(spit "newfile.txt" s)

Это создает newfile.txt, если он не завершает работу и записывает содержимое файла. Если вы хотите добавить в файл, вы можете сделать

(spit "filename.txt" s :append true)

Для чтения или записи файла вы также должны использовать программу чтения и записи Java. Они обернуты в пространство имен clojure.java.io:

(ns file.test
  (:require [clojure.java.io :as io]))

(let [wrtr (io/writer "test.txt")]
  (.write wrtr "hello, world!\n")
  (.close wrtr))

(let [wrtr (io/writer "test.txt" :append true)]
  (.write wrtr "hello again!")
  (.close wrtr))

(let [rdr (io/reader "test.txt")]
  (println (.readLine rdr))
  (println (.readLine rdr)))
; "hello, world!"
; "hello again!"

Обратите внимание, что разница между slurp / spit и примерами чтения / записи заключается в том, что файл остается открытым (в операторах let) в последнем, а чтение и запись буферизуются, таким образом, более эффективно при многократном чтении / записи в файл.

Вот дополнительная информация: slurp spit clojure.java.io Java BufferedReader Java's Writer

Answer 3

Что касается вопроса 2, иногда хочется, чтобы поток строк возвращался как первоклассный объект. Чтобы получить это как ленивую последовательность и при этом автоматически закрывать файл в EOF, я использовал эту функцию:

(use 'clojure.java.io)

(defn read-lines [filename]
  (let [rdr (reader filename)]
    (defn read-next-line []
      (if-let [line (.readLine rdr)]
       (cons line (lazy-seq (read-next-line)))
       (.close rdr)))
    (lazy-seq (read-next-line)))
)

(defn echo-file []
  (doseq [line (read-lines "myfile.txt")]
    (println line)))

Answer 4

Чтобы читать файл построчно, вам больше не нужно прибегать к взаимодействию:

(->> "data.csv"
      io/resource
      io/reader
      line-seq
      (drop 1))

Это предполагает, что ваш файл данных хранится в каталоге ресурсов и что первая строка содержит информацию заголовка, которую можно отбросить.

Answer 5

Это как прочитать весь файл.

Если файл находится в каталоге ресурсов, вы можете сделать это:

(let [file-content-str (slurp (clojure.java.io/resource "public/myfile.txt")])

не забудьте потребовать / использовать clojure.java.io

Answer 6

(require '[clojure.java.io :as io])
(io/copy (io/file "/etc/passwd") \*out*\)