Получить идентификатор пользователя с сервера метаданных SAS

Question

Я работаю в конфигурации, которая использует IOM для подключения к серверу метаданных - поэтому в моей среде нет автоматических макропеременных для определения идентификатора пользователя (мы используем объединенный сервер рабочей области с общей учетной записью хоста).

Существует ли короткий фрагмент кода, который можно использовать для запроса у сервера метаданных идентификатора пользователя SAS?

Answer 1

Следующее довольно долго наматывается и, вероятно, может быть сокращено - но оно делает свою работу!

data _null_;
call symput('login_id',''); /* initialise to missing */
n = 1;
length loginUri person $ 512;
nobj = metadata_getnobj("omsobj:Login?*",n, loginUri);
if (nobj>0) then do;
    length __uri __objName __porig personUri $256;
    __porig = loginUri;
    __uri = '';
    __objName = '';
    __n = 1;
    __objectFound = 0;
    personUri = "";
    __numObjs = metadata_getnasn(__porig ,"AssociatedIdentity", 1, __uri);
    do until(__n > __numObjs | __objectFound );
        __rc = metadata_getattr(__uri, "PublicType", __objName);
        if __objName="User" then do;
            __rc=metadata_getattr(__uri, "Name", __objName);
            __objectFound = 1;
            personUri = __uri;
        end;
        else do;
            __n = __n+1;
            rc = metadata_getnasn(__porig, "AssociatedIdentity", __n, __uri);
        end;
    end;
    if upcase("N")="Y" and not __objectFound then do;
        put "*ERROR*: Object with  PublicType=" "User" " not found for parent " loginUri " under AssociatedIdentity association";
        stop;
    end;
    ;
    rc = metadata_getattr(personUri, "Name", person);
    call symput("login_id", trim(person));
end;
run;
%put &login_id;

Answer 2

Я не знаю, насколько это коротко... но эта ссылка фокусируется на запросе метаданных.