Родной интерфейс вызова: как перевести "wchar_t"?

Question

Я хотел бы использовать нкурсы int addwstr(const wchar_t *wstr); функция в Perl6.

Как я мог получить подписи Perl 6, который передает const wchar_t *wstr из addwstr?

use v6;
use NativeCall;

constant LIB = 'libncursesw.so.5';

sub addwstr(  ?  ) returns int32 is native(LIB) is export {*};

Answer 1

wchar_t 32 бита на моей машине. Из документа NativeCall вы можете объявить их массив, а имя массива будет действовать как указатель;

#!/usr/bin/env perl6
use v6;
use NCurses;                   # To get iniscr(), endwin() etc
use NativeCall;

# Need to run setlocale from the C library
my int32 constant LC_ALL = 6;           # From locale.h
my sub setlocale(int32, Str) returns Str is native(Str) { * }

constant LIB = 'libncursesw.so.5';
sub addwstr(CArray[int32]) returns int32 is native(LIB) { * }

# The smiley        : Codepoint 0x263a
# Latin space       : Codepoint 0x20  (Ascii decimal ord 32)
# Check mark (tick) : Codepoint 0x2713

my CArray[int32] $wchar_str .= new(0x263a, 0x20, 0x2713);

setlocale(LC_ALL, "");
initscr();
move(2,2);
addwstr( $wchar_str );
nc_refresh;
while getch() < 0 {};
endwin;

Это печатает "☺ ✓" на моей машине. Это не работает без вызова setlocale.

Кроме того, вам не нужно использовать функции 'w' - вы можете просто передать обычные строки perl6 (предположительно кодированные UTF-8), и это просто работает. Это дает тот же результат;

#!/usr/bin/env perl6
use v6;
use NCurses;
use NativeCall;

# Need to run setlocale from the standard C library
my int32 constant LC_ALL = 6;           # From locale.h
my sub setlocale(int32, Str) returns Str is native(Str) { * }

my $ordinary_scalar = "☺ ✓";

setlocale(LC_ALL, "");
initscr();
move(2,2);
addstr( $ordinary_scalar );   # No 'w' necessary
nc_refresh;
while getch() < 0 {};
endwin;