В чем разница между хэшем и хеш-ссылкой в ​​Perl?

Я хотел бы правильно понимать хэши в Perl. Мне приходилось использовать Perl с перерывами в течение довольно долгого времени, и в основном всякий раз, когда мне нужно это делать, это в основном связано с обработкой текста.

И каждый раз, когда мне приходится иметь дело с хэшами, это запутывается. Я нахожу синтаксис очень загадочным для хэшей

Очень хотелось бы получить хорошее объяснение хешей и ссылок на хеш, их различий, когда они требуются и т. Д.

Источник

4 ответа

Решение

Простой хеш близок к массиву. Их инициализации даже похожи. Первый массив:

@last_name = (
  "Ward",   "Cleaver",
  "Fred",   "Flintstone",
  "Archie", "Bunker"
);

Теперь давайте представим ту же информацию с помощью хэша (он же ассоциативный массив):

%last_name = (
  "Ward",   "Cleaver",
  "Fred",   "Flintstone",
  "Archie", "Bunker"
);

Хотя они имеют одинаковое имя, массив @last_name и хэш %last_name полностью независимы.

С массивом, если мы хотим узнать фамилию Арчи, мы должны выполнить линейный поиск:

my $lname;
for (my $i = 0; $i < @last_name; $i += 2) {
  $lname = $last_name[$i+1] if $last_name[$i] eq "Archie";
}
print "Archie $lname\n";

С хешем это намного более синтаксически:

print "Archie $last_name{Archie}\n";

Скажем, мы хотим представлять информацию только с немного более богатой структурой:

  • Кливер (фамилия)
    • Уорд (имя)
    • Июнь (имя супруга)
  • кремень
    • Фред
    • Вильма
  • бункерный
    • Арчи
    • Эдит

До появления ссылок плоские хэши "ключ-значение" были лучшими, что мы могли сделать, но ссылки позволяют

my %personal_info = (
    "Cleaver", {
        "FIRST",  "Ward",
        "SPOUSE", "June",
    },
    "Flintstone", {
        "FIRST",  "Fred",
        "SPOUSE", "Wilma",
    },
    "Bunker", {
        "FIRST",  "Archie",
        "SPOUSE", "Edith",
    },
);

Внутренне, ключи и значения %personal_info все скаляры, но значения представляют собой особый вид скаляров: хеш-ссылки, созданные с {}, Ссылки позволяют нам моделировать "многомерные" хеши. Например, мы можем добраться до Вилмы через

$personal_info{Flintstone}->{SPOUSE}

Обратите внимание, что Perl позволяет нам опускать стрелки между индексами, поэтому приведенное выше эквивалентно

$personal_info{Flintstone}{SPOUSE}

Это очень много печатать, если вы хотите узнать больше о Фреде, так что вы можете взять ссылку как курсор:

$fred = $personal_info{Flintstone};
print "Fred's wife is $fred->{SPOUSE}\n";

Так как $fred во фрагменте выше есть хэшреф, стрелка нужна. Если вы оставите это, но умно включен use strict чтобы помочь вам поймать эти виды ошибок, компилятор будет жаловаться:

Global symbol "%fred" requires explicit package name at ...

Ссылки на Perl похожи на указатели в C и C++, но они никогда не могут быть нулевыми. Указатели в C и C++ требуют разыменования, как и ссылки в Perl.

Параметры функций C и C++ имеют семантику передачи по значению: они просто копии, поэтому модификации не возвращаются к вызывающей стороне. Если вы хотите увидеть изменения, вы должны передать указатель. Вы можете получить этот эффект с помощью ссылок в Perl:

sub add_barney {
    my($personal_info) = @_;

    $personal_info->{Rubble} = {
        FIRST  => "Barney",
        SPOUSE => "Betty",
    };
}

add_barney \%personal_info;

Без обратной косой черты, add_barney получил бы копию, которая выбрасывается, как только саб возвращается.

Обратите внимание также на использование "жирной запятой" (=>) выше. Он автоматически цитирует строку слева и делает синтаксически шумную инициализацию хеша.

Источник

Ниже показано, как вы можете использовать хеш и ссылку на хеш:

my %hash = (
    toy    => 'aeroplane',
    colour => 'blue',
);
print "I have an ", $hash{toy}, " which is coloured ", $hash{colour}, "\n";

my $hashref = \%hash;
print "I have an ", $hashref->{toy}, " which is coloured ", $hashref->{colour}, "\n";

Также см. Perldoc perldsc.

Источник

Хеш - это основной тип данных в Perl. Он использует ключи для доступа к своему содержимому.

Ссылка на хеш - это сокращение от ссылки на хеш. Ссылки - это скаляры, то есть простые значения. Это скалярное значение, которое по существу содержит указатель на сам фактический хеш.

Ссылка: разница между хэшем и хэшем ref в perl - Форумы Ubuntu

Разница также в синтаксисе для удаления. Как и C, Perl работает следующим образом:

delete $hash{$key};

и для хеш-ссылок

delete $hash_ref->{$key};

Perl Hash Howto - отличный ресурс для понимания хешей и хешей с помощью хеш-ссылок

Здесь также есть другая ссылка, которая содержит больше информации о Perl и ссылках.

Источник

Смотрите perldoc perlreftut, который также доступен в командной строке вашего компьютера.

Ссылка - это скалярное значение, которое относится ко всему массиву или целому хешу (или к чему-либо еще). Имена являются одним из видов ссылок, с которыми вы уже знакомы. Вспомните президента Соединенных Штатов: грязный, неудобный мешок с кровью и костями. Но чтобы говорить о нем или представлять его в компьютерной программе, все, что вам нужно, - это простая и удобная скалярная строка "Барак Обама".

Ссылки в Perl похожи на имена для массивов и хэшей. Это частные, внутренние имена Perl, так что вы можете быть уверены, что они однозначны. В отличие от "Барака Обамы", ссылка относится только к одной вещи, и вы всегда знаете, к чему она относится. Если у вас есть ссылка на массив, вы можете восстановить весь массив из него. Если у вас есть ссылка на хеш, вы можете восстановить весь хеш. Но ссылка все еще является простым, компактным скалярным значением.

Источник
Другие вопросы по тегам