Как преобразовать структуру объекта Erlang в Elixir Map?

Question

Я использую couchbeam, чтобы связаться с CouchDB от Elixir.

Но библиотека возвращает мне старое представление объекта Erlang, как {[{"foo", "bar"}]} а не карты эликсира, это было связано с использованием jiffy: decode без lib return_mapsКак мне преобразовать эту структуру объекта в карты эликсира (и наоборот)?

Я нашел хакерский способ jiffy: закодировать и jiffy: расшифровать его снова с return_maps... но должна быть другая альтернатива?

Обновить:

Из примера Hynek в Erlang, это, кажется, работает:

defmodule ToMaps do

  def convert({x}) when is_list(x) do
    Map.new(x, fn {k, v} -> {k, convert(v)} end)
  end

  def convert([head | tail]) do
    [convert(head) | convert(tail)]
  end

  def convert(x) do
    x
  end
end

Кажется, чтобы сделать работу.

iex(1)> ToMaps.convert({[{"foo",[{[{"a",1}]},3]},{"bar","baz"}]})

%{"bar" => "baz", "foo" => [%{"a" => 1}, 3]}

Answer 1

Я не знаю Эликсир, но в Эрланге:

-module(to_maps).

-export([to_maps/1]).

to_maps({L}) when is_list(L) ->
    maps:from_list([{K, to_maps(V)} || {K, V} <- L]);
to_maps([H|T]) ->
    [to_maps(H) | to_maps(T)];
to_maps(X) -> X.

Редактировать:

Задний ход:

from_maps(#{} = M) ->
    F = fun(K, V, Acc) -> [{K, from_maps(V)} | Acc] end,
    {maps:fold(F, [], M)};
from_maps([H|T]) ->
    [from_maps(H) | from_maps(T)];
from_maps(X) -> X.

Я бы не советовал, но это может быть даже одна функция:

convert({L}) when is_list(L) ->
    maps:from_list([{K, convert(V)} || {K, V} <- L]);
convert(#{} = M) ->
    F = fun(K, V, Acc) -> [{K, convert(V)} | Acc] end,
    {maps:fold(F, [], M)};
convert([H|T]) ->
    [convert(H) | convert(T)];
convert(X) -> X.

Использование:

1> jiffy:decode(<<"{\"foo\":[3, {\"a\":1}], \"bar\":\"baz\"}">>).
{[{<<"foo">>,[3,{[{<<"a">>,1}]}]},{<<"bar">>,<<"baz">>}]}
2> to_maps:to_maps(v(-1)).
#{<<"bar">> => <<"baz">>,<<"foo">> => [3,#{<<"a">> => 1}]}
3> to_maps:from_maps(v(-1)).
{[{<<"foo">>,[3,{[{<<"a">>,1}]}]},{<<"bar">>,<<"baz">>}]}
4> to_maps:convert(v(-1)).
#{<<"bar">> => <<"baz">>,<<"foo">> => [3,#{<<"a">> => 1}]}
5> to_maps:convert(v(-1)).
{[{<<"foo">>,[3,{[{<<"a">>,1}]}]},{<<"bar">>,<<"baz">>}]}
6> to_maps:convert(v(-1)).
#{<<"bar">> => <<"baz">>,<<"foo">> => [3,#{<<"a">> => 1}]}
...

Answer 2

Мне нужно увидеть всю вашу структуру данных, чтобы сказать наверняка, но вы можете использовать что-то вроде этого:

iex(1)> Enum.into([{"foo", "bar"}], %{})
%{"foo" => "bar"}