Как загрузить поток с файлом, скопированным в буфер обмена Windows

Question

Я скопировал файл в буфер обмена Windows (просто щелкнув правой кнопкой мыши, скопируйте). Я хотел бы загрузить потомка TStream с файлом, который в данный момент хранится в буфере обмена.

uses
  Classes, Clipbrd;

MyStream := TMemoryStream.Create;
try
  //here i would like to load the clipboard file into MyStream
finally
  MyStream.Free;
end;

Answer 1

Когда вы копируете файл в буфер обмена с жесткого диска, он просто копирует полный путь к файлу и имя файла в CF_HDROP формат. Вы можете использовать DragQueryFile() функция для чтения имен файлов, например:

uses
  Classes, Clipbrd, ShellAPI;

var
  hDrop: THandle
  MyStream: TMemoryStream;
  Files: TStringList;
  NumFiles, FileIdx: DWORD;
  FileName: array[0..MAX_PATH] of Char;
  I: Integer;
begin
  Files := TStringList.Create;
  try
    Clipboard.Open;
    try
      if Clipboard.HasFormat(CF_HDROP) then
      begin
        // DO NOT free this handle, the clipboard owns it!
        hDrop := Clipboard.GetAsHandle(CF_HDROP);
        NumFiles := DragQueryFile(hDrop, $FFFFFFFF, nil, 0);
        if NumFiles <> 0 then
        begin
          for FileIdx := 0 to NumFiles-1 do
          begin
            if DragQueryFile(hDrop, FileIdx, FileName, MAX_PATH) <> 0 then
              Files.Add(FileName);
          end;
        end;
      end;
    finally
      Clipboard.Close;
    end;
    for I := 0 to Files.Count-1 do
    begin
      MyStream := TMemoryStream.Create;
      try
        MyStream.LoadFromFile(Files[I]);
        MyStream.Position := 0;
        // use MyStream as needed...
      finally
        MyStream.Free;
      end;
    end;
  finally
    Files.Free;
  end;
end;