Нарушение целостности Data.Set без GeneralizedNewtypeDeriving

Question

Код ниже использует небезопасный GeneralizedNewtypeDeriving расширение, чтобы сломать Data.Set вставляя различные элементы с разными Ord экземпляры:

{-# LANGUAGE GeneralizedNewtypeDeriving #-}
import Data.Set
import System.Random

class AlaInt i where
  fromIntSet :: Set Integer -> Set i
  toIntSet :: Set i -> Set Integer
instance AlaInt Integer where
  fromIntSet = id
  toIntSet = id
newtype I = I Integer deriving (Eq, Show, AlaInt)
instance Ord I where compare (I n1) (I n2) = compare n2 n1 -- sic!  

insert' :: Integer -> Set Integer -> Set Integer
insert' n s = toIntSet $ insert (I n) $ fromIntSet s

randomInput = take 5000 $ zip (randomRs (0,9) gen) (randoms gen) where
    gen = mkStdGen 911

createSet = Prelude.foldr f empty where
    f (e,True) = insert e
    f (e,False) = insert' e

main = print $ toAscList $ createSet randomInput

Код печатает [1,3,5,7,8,6,9,6,4,2,0,9], Обратите внимание, что список неупорядочен и имеет 9 дважды.

Можно ли выполнить эту атаку с использованием словаря, используя другие расширения, например ConstraintKinds? Если да, может Data.Set быть переработан, чтобы быть устойчивым к таким атакам?

Answer 1

Я думаю, что это важный вопрос, поэтому я повторю свой ответ из других источников: вы можете иметь несколько экземпляров одного и того же класса для одного и того же типа в Haskell98 без каких-либо расширений вообще:

$ cat A.hs
module A where
data U = X | Y deriving (Eq, Show)

$ cat B.hs
module B where
import Data.Set
import A
instance Ord U where
    compare X X = EQ
    compare X Y = LT
    compare Y X = GT
    compare Y Y = EQ
ins :: U -> Set U -> Set U
ins = insert

$ cat C.hs
module C where
import Data.Set
import A
instance Ord U where
    compare X X = EQ
    compare X Y = GT
    compare Y X = LT
    compare Y Y = EQ
ins' :: U -> Set U -> Set U
ins' = insert

$ cat D.hs
module D where
import Data.Set
import A
import B
import C
test = ins' X $ ins X $ ins Y $ empty

$ ghci D.hs
Prelude D> test
fromList [X,Y,X]

И да, вы можете предотвратить подобные атаки, храня словарь внутри:

data MSet a where MSet :: Ord a => Set a -> MSet a