Работает ли FindWindow в FMX?

Question

Работает ли FindWindow в FMX?

Я пытаюсь обмениваться данными между двумя приложениями в Windows. Я использую пример из Zarko Gajic. Он использует сообщения Windows, и пример отлично работает. Есть отправитель и приложение-получатель, а также некоторые общие данные: все они закодированы для VCL. Код показан ниже.

unit SenderMain;

{ How to send information (String, Image, Record) between two Delphi applications
http://delphi.about.com/od/windowsshellapi/a/wm_copydata.htm

Learn how to send the WM_CopyData message between two Delphi
applications to exchange information and make two applications
communicate. The accompanying source code demonstrates how to
send a string, record (complex data type) and even graphics
to another application.

~Zarko Gajic
About Delphi Programming
http://delphi.about.com
}
interface

uses
   Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
   Dialogs, StdCtrls, ExtCtrls, TlHelp32,
   shared_data;

type
  TSenderMainForm = class(TForm)
    Button_Send_Data: TButton;
    Log: TListBox;

    procedure Button_Send_DataClick   (Sender: TObject);

   protected
      procedure Loaded; override;
      procedure SendString (send_string: aString);
   end; // Class: TSenderMainForm //

var
   SenderMainForm: TSenderMainForm;

implementation

{$R *.dfm}

{**************** NextWindow ****************}
function NextWindow (wnd: Thandle; list: Tstringlist):boolean; stdcall;
{This is the callback function which is called by EnumWindows procedure
 for each top-level window.  Return "true" to keep retrieving, return
 "false" to stop EnumWindows  from calling}
var
   title: array [0..255] of char;
   receiverHandle: HWND;//THandle;
   win_name: PChar;
   s: AnsiString;
begin
   getwindowtext (wnd, title, 256);
   s := AnsiString (pchar(@title));
   if (s <> '') and (list.indexof (string (s)) < 0) then
   begin
      win_name := PaString (s);
      receiverHandle := FindWindow (win_name, nil); // Find receiving app
      s := AnsiString (Format ('%s (%d)', [s, receiverHandle]));
      list.add (string (s));
   end; // if
   result:=true;
end;

procedure TSenderMainForm.Loaded;
begin
   inherited Loaded;

   enumwindows (@nextwindow, lparam (Log.Items)); {pass the list as a parameter}
end;

procedure TSenderMainForm.SendString (send_string: aString);
var copyDataStruct: TCopyDataStruct; { Declared in Windows.pas: TCopyDataStruct}
    receiverHandle: THandle;
    res: integer;
begin
// Copy string to CopyDataStruct
   copyDataStruct.dwData := 1; //use it to identify the message contents
   copyDataStruct.cbData := (1 + Length (send_string)) * SizeOf (Char);
   copyDataStruct.lpData := PaString (send_string);

   receiverHandle := FindWindow (PaString (cClassName), nil); // Find receiving app
   if receiverHandle = 0 then // not found
   begin
      Log.Items.Add ('CopyData Receiver NOT found!');
   end else // found, send message
   begin
      res := SendMessage (receiverHandle, WM_COPYDATA, Integer(Handle), Integer(@copyDataStruct));
      Log.Items.Add (Format ('String sent, len = %d, result = %d', [copyDataStruct.cbData, res]));
      Log.Items.Add ('"' + PaString (copyDataStruct.lpData) + '"');
   end; // if
end; // SendString

procedure TSenderMainForm.Button_Send_DataClick (Sender: TObject);
begin
   SendString (ParamStr (0));
end;
    ====================== Unit copyDataReceiver ================
unit ReceiverMain;
{ How to send information (String, Image, Record) between two Delphi applications
http://delphi.about.com/od/windowsshellapi/a/wm_copydata.htm }
interface

uses
   Windows, Messages,
   SysUtils, Variants, Classes, Graphics, Controls, Forms,
   Dialogs, StdCtrls, ExtCtrls, shared_data;

type
  TReceiverMainForm = class (TForm)
    Log: TListBox;

    procedure FormCreate(Sender: TObject);

  private
    procedure WMCopyData (var Msg: TWMCopyData); message WM_COPYDATA;
    procedure WMSignalClose (var Msg: TMessage);  message WM_SIGNAL_CLOSE;

    procedure HandleCopyDataString (copyDataStruct: PCopyDataStruct);
  end;

var ReceiverMainForm: TReceiverMainForm;

implementation

{$R *.dfm}

procedure TReceiverMainForm.FormCreate (Sender: TObject);
begin
  Log.Clear;
end;

procedure TReceiverMainForm.WMSignalClose (var Msg: TMessage);
var pfn: PaString;
    fn: aString;
begin
   Log.Items.Add (Format ('Signal received, WParam = %d, LParam = %d', [Msg.WParam, Msg.LParam]));
   pfn := PaString (Msg.LParam);
   fn  := aString (pfn);
   Log.Items.Add (fn);
end;

procedure TReceiverMainForm.WMCopyData (var Msg: TWMCopyData);
var copyDataType: Int32;
begin
   copyDataType := Msg.CopyDataStruct.dwData;

   //Handle of the Sender
   Log.Items.Add (Format ('WM_CopyData (type: %d) from: %d', [copyDataType, msg.From]));
   HandleCopyDataString (Msg.CopyDataStruct);

   //Send something back
   msg.Result := Log.Items.Count;
end;

procedure TReceiverMainForm.HandleCopyDataString (copyDataStruct: PCopyDataStruct);
var mess: aString;
begin
   mess := aString (PaString (copyDataStruct.lpData));
   Log.Items.Add (Format ('Received string of length %d at %s', [Length (mess), DateToStr (Now)]));
   Log.Items.Add ('"' + mess + '"');
end;

end.
    ================ unit shared_data ==========================
unit shared_data;

interface

uses Messages;

const
   WM_SIGNAL_CLOSE = WM_APP + 2012;
   ARG_AMI_1       = 285;
   ARG_AMI_2       = 1;
   cClassName      = 'TReceiverMainForm';

type
   aString  = string;
   PaString = PChar;

implementation

end.

Суть приложения отправителя в том, что оно отправляет WM_COPYDATA получателю. Чтобы найти получателя, FindWindow используется с именем принимающего приложения (жестко запрограммировано), которое возвращает дескриптор окна. Если дескриптор равен нулю, отображается ошибка.

Когда я дублирую это в приложении FMX, возникают проблемы. Приемная часть FMX не работает, в то время как приемник VCL может получать сообщения от отправителя VCL или отправителя FMX. Код FMX-приемника показан ниже.

Поскольку я не был уверен в названии окон, я перечислил все окна, добавил числовой дескриптор к каждому имени окна и показал его в списке в отправителе. Все ручки равны нулю. У меня есть два вопроса:

Почему все ручки равны нулю в перечислении?
Почему я не могу отправить сообщение на приемное устройство FMX?

Любая помощь будет принята с благодарностью.

unit copyDataReceiver;

interface

uses
   System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
   FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.Layouts, FMX.ListBox,
   Windows, Messages, shared_data;

type
   TReceiverMainForm = class (TForm)
    Log: TListBox;

    procedure FormCreate(Sender: TFMXObject);

  private
    procedure WMCopyData (var Msg: TWMCopyData); message WM_COPYDATA;
    procedure WMSignalClose (var Msg: TMessage);  message WM_SIGNAL_CLOSE;

    procedure HandleCopyDataString (copyDataStruct: PCopyDataStruct);
  end;

var ReceiverMainForm: TReceiverMainForm;

implementation

{$R *.fmx}

procedure TReceiverMainForm.FormCreate (Sender: TFMXObject);
begin
  Log.Clear;
end;

procedure TReceiverMainForm.WMSignalClose (var Msg: TMessage);
var pfn: PaString;
    fn: aString;
begin
   Log.Items.Add (Format ('Signal received, WParam = %d, LParam = %d', [Msg.WParam, Msg.LParam]));
   pfn := PaString (Msg.LParam);
   fn  := aString (pfn);
   Log.Items.Add (fn);
end;

procedure TReceiverMainForm.WMCopyData (var Msg: TWMCopyData);
var copyDataType: Int32;
begin
   copyDataType := Msg.CopyDataStruct.dwData;

   //Handle of the Sender
   Log.Items.Add (Format ('WM_CopyData (type: %d) from: %d', [copyDataType, msg.From]));
   HandleCopyDataString (Msg.CopyDataStruct);

   //Send something back
   msg.Result := Log.Items.Count;
end;

procedure TReceiverMainForm.HandleCopyDataString (copyDataStruct: PCopyDataStruct);
var mess: aString;
begin
   mess := aString (PaString (copyDataStruct.lpData));
   Log.Items.Add (Format ('Received string of length %d at %s', [Length (mess), DateToStr (Now)]));
   Log.Items.Add ('"' + mess + '"');
end;

end.

0

windows delphi firemonkey sendmessage

Источник

user622097 17 авг '15 в 19:32

2 ответа

Другие вопросы по тегам windows delphi firemonkey sendmessage

user10176765 03 авг '18 в 14:23 2018-08-03 14:23 · Answer 1 · 2018-08-03 14:23

Почему я не могу отправить сообщение на приемное устройство FMX?

Для VCL-форм ClassName получается из имени формы, просто добавляя начальную букву "T" к имени. Например, если у вас есть форма с именем MyForm, ClassName - это TMyForm. Self.ClassName возвращает это имя и вызов Winapi.Windows.FindWindow(PChar(Self.ClassName), nil) возвращает правильный дескриптор.

С FMX-формами вы получите ClassName, построенный аналогичным образом. Для FMX-форм ClassName выводится из имени формы путем добавления ведущего FMT к имени формы. ClassName возвращается Self.ClassNameОднако такой же, как и для VCL-форм.

Например, если у вас есть форма с именем MyFMXForm, ClassName будет FMTMyFMXForm, но Self.ClassName возвращается TMyFMXForm, Поэтому попытка получить дескриптор окна с этим ClassName не удалась. Правильный вызов Winapi.Windows.FindWindow(PChar('FMTMyFMXForm'), nil));,

user505088 17 авг '15 в 19:36 2015-08-17 19:36 · Answer 2 · 2015-08-17 19:36

FindWindow работает точно так же под FMX. Проблема в том, что отправка сообщений в найденное окно не приведет к их перенаправлению обработчикам сообщений формы.

Вместо этого вы должны делать то, что вы всегда должны были делать, даже с VCL. То есть используйте известное окно, временем жизни которого вы управляете. Помните, что окна VCL подвержены отдыху. Другими словами, у вас может быть дескриптор окна для окна в другом процессе, но это окно может быть уничтожено, прежде чем вы получите возможность отправить ему свое сообщение.

Решите это с помощью AllocateHWnd или же CreateWindow создать окно, которое не будет воссоздано. Окно, жизнь которого вы контролируете. Вам нужно будет придумать, как другой процесс обнаружит ваше окно. Лично я бы использовал CreateWindow с известным именем класса, а затем перечислить окна верхнего уровня с EnumWindows ищу окна что то имя класса.