Emacs isearch с автоматическим применением регулярного выражения между символами

Question

Я хотел бы зацепить Emacs's isearch-forward функция, позволяющая автоматически применять регулярные выражения между входными символами при поиске строки. Например, я хотел бы установить это регулярное выражение [-=<>], Если я сейчас наберу foobar в isearch, он должен совпадать foo<bar, fo=ob=>ar, f-o-o-b-a-r, так далее.

Такая функциональность уже доступна? Я смотрел в ELPA и MELPA без успеха. В случае, если это недоступно, и так как мои способности Elisp очень ограничены: как это можно реализовать?

Answer 1

Я написал пакет под названием flex-isearch, который в основном вставляет ".*" между каждым символом строки поиска (это немного сложнее) и переключается на поиск регулярных выражений. Это происходит автоматически при сбое isearch.

Answer 2

ОК, я нашел решение самостоятельно после проверки hexl.el из Emacs.

Вот код

(defun my-isearch-function ()
  "Make isearch skip characters -=<> while searching."
  (if (not isearch-regexp)
      (lambda (string &optional bound noerror count)
        (funcall
         (if isearch-forward
             're-search-forward
           're-search-backward)
         (mapconcat (lambda (c) (regexp-quote (string c))) string
                    "\\(?:[-=<>]*\\)?")
         bound
         noerror
         count))
    (isearch-search-fun-default)))


(defun toggle-my-isearch ()
  "Toggle my search mode.
If activated, incremental search skips characters -=<> while
searching.

For example, searching `foobar' matches `foo-bar' or `f-o-o=b<a>r'."
  (interactive)
  (if (eq isearch-search-fun-function 'isearch-search-fun-default)
      (progn
        (setq isearch-search-fun-function 'my-isearch-function)
        (message "my isearch on"))
    (setq isearch-search-fun-function 'isearch-search-fun-default)
    (message "my isearch off")))


(global-set-key (kbd "s-s") 'toggle-my-isearch)