Разбить строку на подстроки (строки) без разделенных слов

Question

Я работаю в небольшой функции, которая должна разбивать строку в подстроке, чтобы убедиться, что ни одно из слов не будет вырезано.

Давайте возьмем этот вариант использования:

"что-то идет не так, и я не могу понять, в чем проблема"

всего персонажей: 63;

с максимальной длиной символов в 15 в строке я бы получил этот субстрат "что-то идет"

как вы можете видеть, это сокращает слово, когда я хотел бы получить все слово.

строка [1]: что-то // разрывает строку в последнем пробеле ниже максимальной длины символов;

строка [2]: идет не так.... // включает пропущенные символы из первой строки в начале второй строки

строка [3]: .... // и так далее, пока все символы не будут зациклены.

Я придумала это решение, которое сводит меня с ума.

function splitString(obj:Object):Array{

if (obj.hasOwnProperty("d_string"))
{
    var texto:String = obj.d_string;

    var textoStr:Array = texto.split("");
    var textoLen:Number = texto.length;
    trace("textoLen " + textoLen);

    var maxCharPerLine:Number;
    if (obj.hasOwnProperty("d_limit")){
        maxCharPerLine = obj.d_limit;
        trace("maxCharPerLine" + maxCharPerLine);
    }else{
        maxCharPerLine = 20;
    }


    var textLine:Array = [];

    var currentLine:Number = 1;
    var currentIndex:Number = 0;


    var cachedCharsForLine:Array = [];      //all characters between the range
    var lastCachedCharsForLine:Array = [];  //mirror of all characters stoping at the last space found
    var missingChars:Array = [];


    var canCleanData:Boolean = false;



    /*START LOOPING OVER THE STRING*/   
    for (var i:Number = 0; i< textoLen; i++) 
    {   
        //<block1>
        if ( currentIndex == maxCharPerLine || i == textoLen -1 ){ 
            canCleanData = true;
        }
        //<block2> 22
        if ( currentIndex <= maxCharPerLine ){ 
            cachedCharsForLine.push(textoStr[i]);
            //trace(cachedCharsForLine);
        }



            trace(textoStr[i]);
            trace(textoStr[i] == " ");


            /*is the characters a space?*/
            if (textoStr[i] == " ") {
                /*1. even after the condition above returns false*/
                lastCachedCharsForLine = [];
                lastCachedCharsForLine = cachedCharsForLine;
            }


            /*as you can see from the output this value is being updated every iteration after the first space get found
            when it was suppose to be updated only if the a char of type <space> get found"
            */
            trace("-----------------" + lastCachedCharsForLine)


        //<block4>
        if( currentIndex == maxCharPerLine || i == textoLen -1 ){       

            if (textoStr[i]==" " || textoStr[i+1]==" "){        
                trace("\n A");
                //trace("@@@      " + lastCachedCharsForLine);
                textLine[currentLine] = lastCachedCharsForLine;
                trace("//" + textLine[currentLine]);
            }
            else{
                trace("\n B");
                //trace("@@@      " + lastCachedCharsForLine);
                textLine[currentLine] = lastCachedCharsForLine;
                trace("//" + textLine[currentLine]);
            }

            currentIndex = 0;
            currentLine ++;
        }

        //<block5>
        if (currentLine > 1 && canCleanData){
            trace("DATA CLEANED");
            canCleanData = false;
            cachedCharsForLine = [];
            lastCachedCharsForLine = [];
        }

        currentIndex ++;
    }
    return textLine;
}else{
    return textLine[0] = false;
}

}



var texto:String = "Theres something going wrong and it's driving me crazy.";
var output:Array = []
output = splitString({"d_string":texto,"d_limit":15});

for (var i:Number = 0; i<output.length; i++){
    trace(output[i] + "\n\n");  
}

Переменная lastCachedCharsForLine обновляется, как вы можете видеть из этой линии трассировки.

trace("-----------------" + lastCachedCharsForLine)

даже при условии возврата ниже ложного

 if (textoStr[i] == " ") {
                    /*1. even after the condition above returns false*/
                    lastCachedCharsForLine = [];
                    lastCachedCharsForLine = cachedCharsForLine;
                }

Answer 1

Это было довольно весело. Код ниже выводов:

|-------------|
something is
going wrong
and i can't
figure out
what's the
problem.
WORDTHATISWAYTOOLONGFORTHEBUFFER.
A quick brown
fox jumped
over the lazy
dog.

package {

    import flash.display.Sprite;

    final public class Test2 extends Sprite {

        public function Test2() {

            splitIntoLines("something is going wrong and i can't figure out what's the problem.  WORDTHATISWAYTOOLONGFORTHEBUFFER. A quick brown fox jumped over the lazy dog.");

        }

        private function splitIntoLines(text:String, maxLineLength:int = 15):void {
            const words:Array   = text.split(/\s+/);
            const output:Array  = [];

            var buffer:String   = '';
            while (words.length) {

                var word:String = words.shift() as String;

                // if buffer has something, add a space
                if (buffer.length) {

                    if (buffer.length + word.length + 1 < maxLineLength) {
                        buffer += ' ' + word;
                    } else {
                        output.push(buffer);
                        buffer = word;
                    }

                // otherwise, it's the first word
                } else {

                    if (buffer.length + word.length < maxLineLength) {
                        buffer += word;
                    } else {
                        output.push(buffer);
                        buffer = word;
                    }
                }
            }

            // something is still in there?
            if (buffer.length) {
                output.push(buffer);
            }

            trace(output.join('\n'));

        }
    }
}

Answer 2

Это, вероятно, сделает вашу жизнь проще, если вы используете Грант Скиннер StringUtils Lib:

http://gskinner.com/blog/archives/2007/04/free_extension.html

truncate Метод это то, что вы ищете:

var line:String = "Something is going wrong and I can't figure out what's the problem."
var truncatedLine:String = StringUtils.truncate(line, 15, "...");