SPARQL Отрицание: Все безразлично: Агенты, которые не безошибочно: Персоны

Question

Я пытаюсь написать запрос SPARQL, который должен дать мне все foaf:Agents которые не foaf:Persons,

Я не вижу способа применения этой конструкции OPTIONAL/BOUND к этой проблеме, потому что все свойства, такие как rdfs:subClassOf а также rdf:type транзитивны и рефлексивны.

Я попробовал это:

SELECT * WHERE { 
?x rdf:type foaf:Agent 
OPTIONAL { ?y rdf:type foaf:Person } 
FILTER ( !BOUND(?y) ) }

Но rdf:type кажется транзитивным, по крайней мере, с JENA/ARQ/SDB.

Answer 1

Причина, по которой это не работает, заключается в том, что у вас есть две отдельные привязки переменных (?x а также ?y), которые не имеют отношения к вашему запросу. Так ?x должен быть обязательно указан в наборе результатов (что вам нужно), но если ?y не связан, вы не узнали ничего нового о ?x,

Обновление: в идеальном запросе не было бы необходимости ?y совсем; Вы можете проверить входящие / исходящие edegs ?x непосредственно. Это трудно (невозможно?) Сделать в SPARQL 1.0, когда вы хотите проверить, не существует ли ребро для данной привязки переменной. Тем не менее, SPARQL 1.1 обеспечит поддержку отрицания:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
PREFIX foaf: <http://xmlns.com/foaf/0.1/> 

SELECT ?agent
WHERE 
{
    ?agent rdf:type foaf:Agent .
    FILTER NOT EXISTS { ?agent rdf:type foaf:Person . }
}

Подход @Kingsley Idehen (с использованием сторонних расширений SPARQL) должен помочь вам решить проблему в краткосрочной перспективе.

Answer 2

Чтобы сделать это в SPARQL 1.0, вам нужно написать:

SELECT * WHERE { 
     ?x rdf:type foaf:Agent 
     OPTIONAL { ?y rdf:type foaf:Person . FILTER (?x = ?y) . } 
     FILTER ( !BOUND(?y) ) 
}

Как говорит Фил М, в SPARQL 1.1 будет введен новый синтаксис, чтобы сделать его намного проще для написания.

Answer 3

Вот (черновик) спецификации SPARQL 1.1 для отрицания: http://www.w3.org/TR/sparql11-query/

Answer 4

Через Virtuoso SPARQL Extensions конечную точку для проверки http://lod.openlinksw.com/sparql (экземпляр LOD Cloud Cache)

SELECT distinct ?x ?o 
WHERE { 
?x a foaf:Agent .
?x ?p ?o.
filter (!bif:exists ((select (1) where { ?x a foaf:Person } ))) 
} 
limit 10

DESCRIBE ?x 
WHERE { 
?x a foaf:Agent .
filter (!bif:exists ((select (1) where { ?x a foaf:Person } ))) 
} 
limit 200 

Answer 5

Следующее теперь работает, благодаря SPARQL 1.1:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
PREFIX foaf: <http://xmlns.com/foaf/0.1/> 
SELECT DISTINCT COUNT(?agent)
WHERE 
{
    ?agent rdf:type foaf:Agent .
    FILTER (NOT EXISTS { ?agent rdf:type foaf:Person . })
}

Живые примеры ссылок:

1. Решение для запроса

2. Определение запроса