Что не так с этой грамматикой? (ANTLRWorks 1.4)

Question

У меня есть следующий код, написанный в ANTLRWorks 1.4

grammar hmm;

s           :   (put_a_in_b)|(put_out_a)|(drop_kick)|(drop_a)|(put_on_a);

put_a_in_b  :   (PUT_SYN)(ID)(IN_SYN)(ID);  
put_out_a   :   (PUT2_SYN)(OUT_SYN)(ID) | (E1)(ID); 
drop_kick   :   ('drop')('kick')(ID);
drop_a      :   (DROP_SYN)(ID);
put_on_a    :   (E2)(ID);

PUT_SYN     :   'put' | 'place' | 'drop';
PUT2_SYN    :   'put' | 'douse';
IN_SYN      :   'in' | 'into' | 'inside' | 'within';    
OUT_SYN     :   'out';
E1          :   'extinguish'|'douse';
DROP_SYN    :   'drop' | 'throw' | 'relinquish';
WS          :   ( ' '  | '\t' | '\r' | '\n' ) {$channel=HIDDEN;};
ID          :   ('a'..'z'|'A'..'Z'|'_') ('a'..'z'|'A'..'Z'|'0'..'9'|'_')*;
E2          :   'put on'|'don'|'wear';
COMMENT
    :   '//' ~('\n'|'\r')* '\r'? '\n' {$channel=HIDDEN;}
    |   '/*' ( options {greedy=false;} : . )* '*/' {$channel=HIDDEN;}
    ;

Когда я запускаю его с вводом:

drop object

Я получаю исключение MismatchedTokenException(5!= 15).

И с входом:

put o1 in o2

Я получаю исключение NoViableAltException.

Хотя это нормально работает с

place o2 in o2

Я новичок в этом, но кажется, что есть неясности? Или, может быть, мое использование ANTLR неверно?

Answer 1

Вы положили 'drop' а также 'put' в двух разных лексер-правилах:

PUT_SYN  : 'put' | 'place' | 'drop';          // drop & put
PUT2_SYN : 'put' | 'douse';                   //        put
...
DROP_SYN : 'drop' | 'throw' | 'relinquish';   // drop

когда put встречается лексером, PUT_SYN всегда будет правило, которое соответствует ему, поэтому 'put' может (или должен) быть удален из PUT2_SYN править.

Итак, ваша проблема с разбором строки drop object: парсер будет пытаться совпадать drop_a : (DROP_SYN)(ID); но "drop" будет соответствовать в правиле лексера PUT_SYN,

РЕДАКТИРОВАТЬ

Эти списки синонимов можно лучше превратить в правила синтаксического анализатора (вместо правил лексера). Вот небольшая демонстрация:

grammar TextAdventure;

parse
  :  command (EndCommand command)* EOF
  ;

command
  :  put_syn_1 OtherWord in_syn OtherWord
  |  put_syn_2 out_syn_1 OtherWord
  |  out_syn_2 OtherWord
  |  Drop Kick OtherWord
  |  drop_syn OtherWord
  ;

drop_syn
  :  Drop
  |  Throw 
  |  Relinquish
  ;

in_syn
  :  In
  |  Into
  |  Inside
  |  Within
  ; 

put_syn_1
  :  Put
  |  Place
  |  Drop
  ;

put_syn_2
  :  Put
  |  Douse
  ;

out_syn_1
  :  Out
  ;

out_syn_2
  :  Extinguish
  |  Douse
  ;

Space      : (' ' | '\t' | '\r' | '\n'){$channel=HIDDEN;};
EndCommand : ';';
Put        : 'put';
Place      : 'place';
Drop       : 'drop';
Douse      : 'douse';
In         : 'in';
Into       : 'into';
Inside     : 'inside';
Within     : 'within';    
Out        : 'out';
Extinguish : 'extinguish';
Throw      : 'throw';
Relinquish : 'relinquish';
Kick       : 'kick';
OtherWord  : ('a'..'z' | 'A'..'Z')+;

При интерпретации следующего источника:

drop object ; put yourself in myshoes ; place it in avase

вы увидите, что ANTLRWorks сгенерирует следующее дерево разбора: