Как отключить автовивификацию в Perl?

Предположим, у вас есть ОГРОМНОЕ приложение, "разработанное";) большой командой. Вот упрощенная модель потенциальной катастрофы, которая может произойти, когда кто-то слишком глубоко проверяет структуру данных. Если невозможно полностью или автоматически отключить автовификацию, как обойти это? Большое спасибо:)!!!!

use strict; use warnings;use Data::Dumper;

my $some_ref = {akey=>{deeper=>1}};
print Dumper($some_ref );
if($some_ref->{deep}{doot} == 1){
    print 'too deep '.$/;
}

if($some_ref->{deep}){
    print 'Already in a deep doot'.$/;
}

print Dumper($some_ref );

Это выводит следующее:

$VAR1 = {
          'akey' => {
                      'deeper' => 1
                    }
        };
Use of uninitialized value in numeric eq (==) at autovivify_test.pl line 5.
Already in a deep doot
$VAR1 = {
          'deep' => {},
          'akey' => {
                      'deeper' => 1
                    }
        };

Да, я знаю, что есть предупреждение, но... может быть слишком поздно.

Эй, ребята, это может помочь помочь сказать, что мой хэш-референс ссылается на связанный HASH.

Может быть, если я реализую хороший метод FETCH, который проверяет проверки глубже в структуре, я легко решу свою проблему?

Я посмотрел на Tie:: StrictHash, Tie:: Hash и perltie. Вот упрощенная версия моего решения:

#!/usr/bin/env perl;
#test_tie.pl

package StrictHash;
use strict; use warnings;
use Tie::Hash;
our @ISA = qw(Tie::StdHash);
use Carp;

sub TIEHASH {
    my $class = shift;
    my $hash = bless {@_}, $class;
    return $hash;
}
##========================================================================
## FETCH fails if applied to a member that doesn't exist.
##========================================================================
sub FETCH {
    my ($hash, $key) = @_;
    Carp::confess "key '$key' does not exist" unless exists $hash->{$key};
    return $hash->{$key};
}
##========================================================================
package main;
use strict;use warnings;use Data::Dumper;
#Imagine StrictHash is in ./StrictHash.pm
#use StrictHash;
my %hash;
tie %hash, 'StrictHash', akey => {deeper=>1} ;  

my $some_ref =\%hash;
print Dumper($some_ref );
if($some_ref->{deep}{doot} == 1){
    print 'too deep '.$/;
}

Чего я достиг, так это прикоснулся только к одному месту в приложении. Теперь все места, такие как if($some_ref->{deep}{doot}) будут вызывать die с помощью трассировки стека. Поэтому я легко их найду и исправлю. И новые сочинения такого рода НЕ будут возможны. Perl хорош и для больших приложений, вам просто нужно знать больше;).

Спасибо вам всем! Я надеюсь, что это помогает другим.

Источник

5 ответов

Решение

Вы можете захотеть использовать объект вместо хеша (см. Moose) или использовать строго связанный хеш. Или вы можете превратить предупреждения в ошибки, если вы действительно хотите:

use warnings NONFATAL => 'all', FATAL => 'uninitialized';
Источник

Относительно новым является autovivification модуль, который позволяет вам сделать это:

no autovivification;

Довольно просто.

Источник

Вы можете заблокировать хеш, используя одну из функций из Hash:: Util (основной модуль).

use Hash::Util qw( lock_keys unlock_keys );

my $some_ref = { akey => { deeper => 1 } };
lock_keys %$some_ref;

print "too deep" if $some_ref->{deep}{shit} == 1;

Теперь последний оператор выдаст исключение:

Attempt to access disallowed key 'deep' in a restricted hash

Недостатком, конечно, является то, что вам нужно быть очень осторожным при проверке ключей в хэше, чтобы избежать исключений, то есть использовать lof of "if exists ...msgstr "проверить ключи перед тем, как получить к ним доступ.

Если вам понадобится добавить ключи к хешу позже, вы можете разблокировать его:

unlock_keys %$some_ref;
$some_ref->{foo} = 'bar'; # no exception
Источник

Я проголосовал за @zoul, но вы должны сделать еще один шаг вперед.

Написать тесты

Ваш код должен быть покрыт тестами, и вы должны запустить некоторые из этих тестов с

use warnings FATAL => 'uninitialized';

заявлено в самом тест-кейсе. Это единственный способ решить проблему, связанную с тем, что разработчики не проверяют все заранее. Убедитесь, что их код проверен.

Сделайте еще один шаг вперед и упростите запуск ваших тестов в http://p3rl.org/Devel::Cover, чтобы получить отчет о покрытии.

cover -delete
PERL5OPT='-MDevel::Cover' prove -l 
cover -report Html_basic

И затем проверьте, что строки кода и операторы выполняются тестами, в противном случае, сделав эти предупреждения фатальными, код просто умрет в неожиданное время спустя.

Источник

Другой вариант - использовать Data::Diver для доступа к вашим структурам данных.

if( 1 == Dive($some_ref, qw/ deep structures are not autovivified now / )) {
    Do_Stuff();
}
Источник
Другие вопросы по тегам