NSIS необслуживаемые варианты

Я хочу построить NSIS-скрипт, который имеет три раздела

  • раздел Главный
  • Малый раздел
  • раздел Общий

Shared является невидимым и будет установлен, если установлен флажок Main или Minor. Если я запускаю установщик, проверяется каждый раздел (основной, второстепенный).

Теперь он должен иметь возможность определить раздел (в режиме без вывода сообщений). Что я должен изменить, чтобы установить только Main или Minor или Both?

Источник

2 ответа

Решение
Name "Test"
Outfile "Test.exe"
;RequestExecutionLevel ?

!include "Sections.nsh"
!include "LogicLib.nsh"
!include "FileFunc.nsh" ;For GetOptions

Page Components "" "" EnforceSectionDependencies
Page InstFiles

Section /o "Main" SID_MAIN
DetailPrint Main
SectionEnd

Section /o "Minor" SID_MINOR
DetailPrint Minor
SectionEnd

Section "" SID_SHARED
DetailPrint Shared
SectionEnd

!macro CheckSectionSwitch sw sid
${GetOptions} $0 '${sw}' $9
${IfNot} ${Errors}
    StrCpy $1 1
    !insertmacro SelectSection ${sid}
${EndIf}
!macroend

Function .onInit
${GetParameters} $0
StrCpy $1 0 ;Any section swithes?
ClearErrors
!insertmacro CheckSectionSwitch '/Main' ${SID_MAIN}
!insertmacro CheckSectionSwitch '/Minor' ${SID_MINOR}

${If} $1 = 0
    ;Set defaults
    !insertmacro SelectSection ${SID_MAIN}
    !insertmacro SelectSection ${SID_MINOR}
${EndIf}

call EnforceSectionDependencies
FunctionEnd

Function EnforceSectionDependencies
!insertmacro UnselectSection ${SID_SHARED}
${If} ${SectionIsSelected} ${SID_MAIN}
${OrIf} ${SectionIsSelected} ${SID_MINOR}
    !insertmacro SelectSection ${SID_SHARED}
${EndIf}
FunctionEnd
Источник

Вам следует обратиться к части управления разделами документации, в частности к SectionSetFlags, чтобы изменить выбор разделов.

Кроме того, может быть полезным будет пример " Как управлять выборками разделов при использовании SubSections & InstTypes".

Источник
Другие вопросы по тегам