VB.Net Проверьте, является ли тип IEnumerable

Question

У меня есть объект System.Type (retType). Я получаю это с отражением от моего объекта политики, который я передаю. Как я могу проверить, можно ли его перечислить? Любая помощь будет наиболее ценимым кодом ниже.

 Public Shared Function SerializeChanges(p As Model.Policy_2.Policy) As XmlDocument

    Dim polProps As PropertyInfo() = p.GetType().GetProperties()
        For Each pi As PropertyInfo In polProps
        Dim retType As Type = pi.PropertyType
       ' This line belowthrows an error that IEnumerable is an Interface and cannot be used as an expression
        If retType Is IEnumerable Then
           'Do Stuff

        End If
End Function

Answer 1

Следующий метод является универсальным методом для проверки того, наследует ли данный тип или реализует другой тип:

Function InheritsOrImplements(child As Type, parent As Type) As Boolean
    If child Is Nothing OrElse parent Is Nothing Then
        Return False
    End If

    parent = resolveGenericTypeDefinition(parent)

    If parent.IsAssignableFrom(child) Then
        Return True
    End If

    Dim currentChild = If(child.IsGenericType, child.GetGenericTypeDefinition(), child)

    While currentChild <> GetType(Object)
        If parent = currentChild OrElse hasAnyInterfaces(parent, currentChild) Then
            Return True
        End If

        currentChild = If(currentChild.BaseType IsNot Nothing AndAlso currentChild.BaseType.IsGenericType, currentChild.BaseType.GetGenericTypeDefinition(), currentChild.BaseType)

        If currentChild Is Nothing Then
            Return False
        End If
    End While

    Return False
End Function

Function hasAnyInterfaces(parent As Type, child As Type) As Boolean
    Return child.GetInterfaces().Any(Function(childInterface) 
        Dim currentInterface = If(childInterface.IsGenericType, childInterface.GetGenericTypeDefinition(), childInterface)

        Return currentInterface = parent

    End Function)
End Function

Function resolveGenericTypeDefinition(type As Type) As Type
    Dim shouldUseGenericType = Not (type.IsGenericType AndAlso type.GetGenericTypeDefinition() <> type)
    If type.IsGenericType AndAlso shouldUseGenericType Then
        type = type.GetGenericTypeDefinition()
    End If
    Return type
End Function

Взято из https://github.com/shaynevanasperen/Quarks/blob/master/Quarks/TypeExtensions/InheritsOrImplements.cs

Использование:

InheritsOrImplements(retType, GetType(IEnumerable))