Есть ли в CoffeeScript "официальный" способ интерполировать строку во время выполнения, а не при компиляции?

Question

У меня есть объект параметров в моем классе CS, и я хотел бы сохранить в нем несколько шаблонов:

class MyClass
    options:
        templates:
            list: "<ul class='#{ foo }'></ul>"
            listItem: "<li>#{ foo + bar }</li>"
            # etc...

Затем я хотел бы интерполировать эти строки позже в коде... Но, конечно, они скомпилированы в "<ul class='" + foo +"'></ul>"и foo не определено.

Есть ли официальный способ CoffeeScript сделать это во время выполнения, используя .replace()?

---

Редактировать: я закончил писать небольшую утилиту, чтобы помочь:

# interpolate a string to replace {{ placeholder }} keys with passed object values
String::interp = (values)->
    @replace /{{ (\w*) }}/g,
        (ph, key)->
            values[key] or ''

Теперь мои варианты выглядят так:

templates:
    list: '<ul class="{{ foo }}"></ul>'
    listItem: '<li>{{ baz }}</li>'

А потом позже в коде:

template = @options.templates.listItem.interp
    baz: foo + bar
myList.append $(template)

Answer 1

Я бы сказал, если вам нужна отложенная оценка, то их, вероятно, следует определить как функции.

Возможно, принимая значения индивидуально:

templates:
    list: (foo) -> "<ul class='#{ foo }'></ul>"
    listItem: (foo, bar) -> "<li>#{ foo + bar }</li>"

Или из объекта контекста:

templates:
    list: (context) -> "<ul class='#{ context.foo }'></ul>"
    listItem: (context) -> "<li>#{ context.foo + context.bar }</li>"

---

Учитывая ваши прежние комментарии, вы можете использовать второй пример выше так:

$(options.templates.listItem foo: "foo", bar: "bar").appendTo 'body'