Пакетный файл для архивации каталога и удаления старого архива 7z

Question

Я давно использовал этот командный файл для резервного копирования определенного каталога на компьютере с Windows Server. Пакетный файл запускается запланированной задачей Windows каждый день в определенное время, и после удаления самого старого файла.7z (7z = www.7-zip.org) он архивирует определенную папку в папку для резервного копирования.

Таким образом, в моей папке с резервными копиями всегда указывается только количество файлов.7z, указанное в BackupNr, и мне не нужно вручную удалять самый старый файл.7z.

Проблема заключается в строке "Set BackupNr=1". Использование BackupNr = 1 У меня всегда есть ДВА архива.7z в моей папке резервных копий после запуска командного файла.

Я не могу понять, что мне нужно изменить, чтобы при запуске командного файла сохранялся только ОДИН архив. Как я могу это исправить?

@echo off

:: The name of the backup file that will be created. It will use the current date as the file name.
@For /F "tokens=1,2,3,4 delims=/ " %%A in ('Date /t') do @(
    Set FileName=%%A%%B%%C%%D
)

:: The name of the folders where all the backup .zip and report files will be stored.
Set ArchiveFolder=D:\Backup\Manual\Archives
Set ReportFolder=D:\Backup\Manual\Reports

:: The name of the folder that will be backed up, i.e. the AppData folder.
Set FolderToBackup=C:\AppData

:: The number of .zip files and .txt reports to keep. Older archives will be deleted according to their age. This ensures we only keep the most recent X number of backups.
Set BackupNr=1

:: Delete oldest backup archives so we only keep the number of archives specified in "skip=".
echo.>> DeletedBackups.txt
date /t >> DeletedBackups.txt
echo.>> DeletedBackups.txt
echo These older backups were deleted:>> DeletedBackups.txt
for /F "skip=%BackupNr% delims=" %%a in ('dir /b /o-d %ArchiveFolder%\*') do (
    echo %ArchiveFolder%\%%a%1>> DeletedBackups.txt
    del /f /q %ArchiveFolder%\%%a%1
)

echo.>> DeletedBackups.txt
echo These older reports were deleted:>> DeletedBackups.txt
for /F "skip=%BackupNr% delims=" %%a in ('dir /b /o-d %ReportFolder%\*') do (
    echo %ReportFolder%\%%a%1>> DeletedBackups.txt
    del /f /q %ReportFolder%\%%a%1
)

echo Starting the backup: %DATE% %TIME% >> %ReportFolder%\%FileName%.txt

:: Adds all files to 7z archive using BCJ2 converter, LZMA with 8 MB dictionary for main output stream (s0), and LZMA with 512 KB dictionary for s1 and s2 output streams of BCJ2.
C:\PROGRA~1\7-Zip\7z.exe a -t7z %ArchiveFolder%\%FileName%.7z %FolderToBackup%\* -m0=BCJ2 -m1=LZMA:d23 -m2=LZMA:d19 -m3=LZMA:d19 -mb0:1 -mb0s1:2 -mb0s2:3 >> %ReportFolder%\%FileName%.txt

echo Backup finished at: %DATE% %TIME% >> %ReportFolder%\%FileName%.txt

:: Write the backup Start and End times to the BackupInfo.csv file.
gawk -f BackupRecord.awk %ReportFolder%\%FileName%.txt >> %ReportFolder%\BackupReport.csv

:: Write the file size of the backup .zip file that was just created to the log file.
set size=0
call :filesize %ArchiveFolder%\%FileName%.7z
echo Backup archive file size: %size% bytes >> %ReportFolder%\%FileName%.txt

exit

:: set filesize of 1st argument in %size% variable, and return
:filesize
  set size=%~z1
  exit /b 0

Благодарю.

Answer 1

Ключ /b в команде dir не использует ни заголовок, ни сводку. Результатом является простой список архивов, в данном случае заказчик по убыванию по времени создания, самый последний первый.

Проблема заключается в пропуске =%BackupNr% в

for /F "skip=%BackupNr% delims=" %%a in ('dir /b /o-d %ReportFolder%\*') do (
  echo %ReportFolder%\%%a%1>> DeletedBackups.txt
  del /f /q %ReportFolder%\%%a%1
)

Как пропустить первую строку, так команда удаления удаляет все архивы, КРОМЕ самого последнего.

затем вы выполняете резервное копирование, поэтому новый файл добавляется в каталог. Результат, два файла.

Если вам нужен только последний, сначала вы должны выполнить резервное копирование и после удаления, или удалить skip=%BackupNr% из команды for.