T-SQL - разделить следующее слово после двух конкретных слов

Question

Представьте, что у меня есть следующая строка: "Выбрать * из таблицы_1 ВНУТРЕННЕЕ СОЕДИНЕНИЕ table_2 ВКЛ table_1.A = table_2.B"

Я хочу извлечь две таблицы оператора для получения: table_1; Таблица 2.

В основном мне нужно получить следующее слово после строки From и Join. Я пытаюсь с помощью следующего запроса:

DECLARE @StaffName nvarchar(4000)
SET @StaffName = 'Select * From table_1 INNER JOIN table_2 ON table_1.A = table_2.B'

SELECT SUBSTRING
  (
    @StaffName,  
        CHARINDEX('From', @StaffName), 
    CHARINDEX(' ', SUBSTRING(@StaffName, CHARINDEX(' ', @StaffName), 255))
  ) ,
    SUBSTRING(@StaffName, CHARINDEX('From ', @StaffName) + 5, LEN(@StaffName))
    ,
    SUBSTRING(@StaffName, CHARINDEX('From ', @StaffName) + 5, LEN(@StaffName))
    ,
    RIGHT(@StaffName,LEN(@StaffName)-CHARINDEX('From ',@StaffName))

Но я не получаю то, что хочу:(

Кто-нибудь может мне помочь?

Большое спасибо!

Answer 1

Глядя на ответ SQLZim, ИДЕАЛЬНО ДЕЙСТВИТЕЛЬНЫЙ (+1), я понял, что устал от извлечения фрагментов строк. Как следствие, я изменил свою функцию синтаксического анализа, чтобы принимать два многосимвольных разделителя. Итак, если вы открыты для UDF, подумайте о следующем:

С другой стороны: будучи табличной функцией, ее легко включить в CROSS APPLY или в один запрос

Для вашего конкретного запроса, мы ищем ключевые слова FROM а также ON

Declare @String varchar(max) = 'Select * From table_1 INNER JOIN table_2 ON table_1.A = table_2.B'
Select Table1 = left(RetVal,charindex(' ',RetVal+' ')-1)
      ,Table2 = right(RetVal,charindex(' ',reverse(RetVal)+' ')-1)
 From [dbo].[udf-Str-Extract] (@String,' from ',' on ')

Возвращает

Table1  Table2
table_1 table_2

Общий пример:

Допустим, мы ищем значения между {}

Declare @String varchar(max) = 'co-101{12345},co-513{22578}'
Select * From [dbo].[udf-Str-Extract] (@String,'{','}')

Возвращает

RetSeq  RetPos  RetLen  RetVal
1       8       5       12345
2       22      5       22578

Еще один общий пример

Declare @String varchar(max) = '<root><firstmame>John</firstname><lastname>Cappelletti</lastname><phone>[phone]</phone></root>'
Select * From [dbo].[udf-Str-Extract] (@String,'>','<')

Возвращает

RetSeq  RetPos  RetLen  RetVal
1       18      4       John
2       44      11      Cappelletti
3       73      14      [phone]

UDF, если интересно

CREATE FUNCTION [dbo].[udf-Str-Extract] (@String varchar(max),@Delimiter1 varchar(100),@Delimiter2 varchar(100))
Returns Table 
As
Return (  

with   cte1(N)   As (Select 1 From (Values(1),(1),(1),(1),(1),(1),(1),(1),(1),(1)) N(N)),
       cte2(N)   As (Select Top (IsNull(DataLength(@String),0)) Row_Number() over (Order By (Select NULL)) From (Select N=1 From cte1 N1,cte1 N2,cte1 N3,cte1 N4,cte1 N5,cte1 N6) A ),
       cte3(N)   As (Select 1 Union All Select t.N+DataLength(@Delimiter1) From cte2 t Where Substring(@String,t.N,DataLength(@Delimiter1)) = @Delimiter1),
       cte4(N,L) As (Select S.N,IsNull(NullIf(CharIndex(@Delimiter1,@String,s.N),0)-S.N,8000) From cte3 S)

Select RetSeq = Row_Number() over (Order By N)
      ,RetPos = N
      ,RetLen = charindex(@Delimiter2,RetVal)-1
      ,RetVal = left(RetVal,charindex(@Delimiter2,RetVal)-1)
 From (Select A.N,RetVal = ltrim(rtrim(Substring(@String, A.N, A.L))) From cte4 A ) A
 Where charindex(@Delimiter2,RetVal)>1
)
/*
Max Length of String 1MM characters

Declare @String varchar(max) = 'Dear [[FirstName]] [[LastName]], ...'
Select * From [dbo].[udf-Str-Extract] (@String,'[[',']]')
*/

Answer 2

Используя комбинацию left(), right(), а также charindex():

declare @str varchar(256) = 'Select * From table_1 INNER JOIN table_2 ON table_1.A = table_2.B';

select 
    tbl1 = left(right(@str,len(@str)-charindex(' From ',@str)-5)
        ,charindex(' ',right(@str,len(@str)-charindex(' From ',@str)-5))-1
       )
  , tbl2 = left(right(@str,len(@str)-charindex(' Join ',@str)-5)
        ,charindex(' ',right(@str,len(@str)-charindex(' Join ',@str)-5))-1
       )

демонстрационный ролик: http://rextester.com/WOO86939

возвращает:

+---------+---------+
|  tbl1   |  tbl2   |
+---------+---------+
| table_1 | table_2 |
+---------+---------+