Google Chart CLJS Clojure

Question

Я попытался адаптировать этот пример в Google Chart. к re-frame фреймворк, reagent, Я хотел бы создать график в режиме реального времени на основе подписок. Я тестировал с простым счетчиком =+-1.

Я получил ошибку: Assert failed: Render must be a function, not nil (ifn? render-fun),

(defn draw-demo-chart 
   [d]
   (let [[columns vectors options chart] (r/children d)
         data (new js/google.visualization.DataTable)]
       (doall ;gotta keep the doall on maps. lazy sequence...
      (map (fn [[type name]]
            (.addColumn data type name)) columns))
      (.addRows data vectors)
      (.draw chart data options)
      (.load js/google "visualization" "1" (clj->js {:packages ["corechart" "orgchart" "calendar" "map" "geochart"]}))     
      (.setOnLoadCallback js/google draw-demo-chart)
      ))


(defn draw-demo-chart-container
    []
    (let [count    (re-frame/subscribe [:count])
          columns  (reaction [["date" "X"] ["number" "Y"]])
          vectors  (reaction (clj->js [[(new js/Date "07/11/14") 145] [(new js/Date "07/12/14") 15]
                                      [(new js/Date "07/13/14") 23] [(new js/Date "07/14/14") 234]]))
          options  (reaction (clj->js {:title (str @count)}))
          chart    (reaction (new js/google.visualization.LineChart (.getElementById js/document "linechart"))) ]
     (fn []
        [draw-demo-graph @columns @vectors @options @chart])))

(def draw-demo-graph 
       (r/create-class {:reagent-render  draw-demo-chart
                        :component-did-mount draw-demo-chart
                        :component-did-update draw-demo-chart}))

Answer 1

Существует несколько проблем с использованием Google Charts API:

1. Он загружается асинхронно и может использоваться только при готовности.

Я предлагаю использовать флаг для записи, готов API или нет, это позволит ему визуализировать, даже если API загружается после монтирования компонента.

(defonce ready?
  (reagent/atom false))

(defonce initialize
  (do
    (js/google.charts.load (clj->js {:packages ["corechart"]}))
    (js/google.charts.setOnLoadCallback
      (fn google-visualization-loaded []
        (reset! ready? true)))))

2. Вам нужно позвонить draw на элементе HTML:

Элемент HTML будет существовать, только если компонент смонтирован. Вы могли бы использовать ref для удобного получения HTML-элемента (в противном случае вам нужно будет либо сохранить ссылку на в файле mount, либо найти его).

(defn draw-chart [chart-type data options]
  [:div
   (if @ready?
     [:div
      {:ref
       (fn [this]
         (when this
           (.draw (new (aget js/google.visualization chart-type) this)
                  (data-table data)
                  (clj->js options))))}]
     [:div "Loading..."])])

Вы захотите перерисовать любое изменение входных данных (которое выше ref пример делает).

3. Настройка источника данных

Я предлагаю удобный метод для получения источника данных:

(defn data-table [data]
  (cond
    (map? data) (js/google.visualization.DataTable. (clj->js data))
    (string? data) (js/google.visualization.Query. data)
    (seqable? data) (js/google.visualization.arrayToDataTable (clj->js data))))

4. Используй это

Теперь вы можете использовать свой график с реактивными значениями!

[draw-chart
    "LineChart"
    @some-data
    {:title (str "Clicks as of day " @day)}]

Полный список кодов находится по адресу https://github.com/timothypratley/google-chart-example