Как использовать для цикла в XSLT и получить значения узлов на основе итерации

Question

Как использовать для цикла в XSLT и получить значения узлов на основе итерации

Как мы используем цикл в XSLT?

У меня есть это требование, где я хочу преобразовать показанный ниже XML в файл, разделенный запятыми. Количество строк в файле CSV будет равно количеству COBRA_Records_within_Range узлы для записи отчета сотрудника. Все значения в 3 строках будут одинаковыми, кроме значений дочерних элементов для COBRA_Records_within_Range узлы. Я могу создать 3 строки, но не могу получить значение для дочерних элементов COBRA_Records_within_Range, Я хочу запустить цикл for для определенного узла, а затем извлечь его дочерние элементы на основе итерации. В приведенном ниже примере есть 3 COBRA_Records_within_Range nodes, Так что цикл должен выполняться для count(COBRA_Records_within_Range)`, а затем в каждой итерации мне нужно значение из его дочерних узлов. Например, если это 2-я итерация, Eligibility_Reason должен отображаться как "Зависимые дочерние элементы - потеря статуса зависимого дочернего элемента в соответствии с правилами плана" в выходных данных CSV.

Может ли кто-нибудь помочь мне с этим?

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <wd:Report_Entry xmlns:wd="urn:com.workday/bsvc">
        <wd:Employee_ID>111111</wd:Employee_ID>
        <wd:Worker>John Smith</wd:Worker>
        <wd:Employee_Last_Name>Smith</wd:Employee_Last_Name>
        <wd:Employee_First_Name>John</wd:Employee_First_Name>
        <wd:COBRA_Records_within_Range>
            <wd:Qualifying_Event_Date>2015-10-04</wd:Qualifying_Event_Date>
            <wd:Eligibility_Reason>Dependent Children - Loss of dependent child status under the
                plan rules</wd:Eligibility_Reason>
            <wd:Benefit_Plan1>Dental-US - Delta Dental PPO BREG</wd:Benefit_Plan1>
        </wd:COBRA_Records_within_Range>
        <wd:COBRA_Records_within_Range>
            <wd:Qualifying_Event_Date>2015-10-05</wd:Qualifying_Event_Date>
            <wd:Eligibility_Reason>Dependent Children - Loss of dependent child status under the
                plan rules</wd:Eligibility_Reason>
            <wd:Benefit_Plan1>Healthcare FSA - Tri-Ad FSA Residential US</wd:Benefit_Plan1>
        </wd:COBRA_Records_within_Range>
        <wd:COBRA_Records_within_Range>
            <wd:Qualifying_Event_Date>2015-10-05</wd:Qualifying_Event_Date>
            <wd:Eligibility_Reason>Spouse - Divorce or legal separation of the covered
                employee</wd:Eligibility_Reason>
            <wd:Test>0</wd:Test>
            <wd:Benefit_Plan1>Medical/Vision-US - Empire Blue Cross &amp; Blue Shield
                EPO</wd:Benefit_Plan1>
        </wd:COBRA_Records_within_Range>
    </wd:Report_Entry>
</root>

Вот ожидаемый результат -

111111, John Smith, Smith, John, 2015-10-04, Dependent Children - Loss of dependent child status under the plan rules, Dental-US - Delta Dental PPO BREG
111111, John Smith, Smith, John, 2015-10-05, Dependent Children - Loss of dependent child status under the plan rules, Healthcare FSA - Tri-Ad FSA Residential US
111111, John Smith, Smith, John, 2015-10-05, Spouse - Divorce or legal separation of the covered employee, Medical/Vision-US - Empire Blue Cross &amp; Blue Shield EPO

Вот XSLT, который я создал -

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xsd="http://www.w3.org/2001/XMLSchema"
    xmlns:op="http://www.w3.org/2005/xpath-functions"
    xmlns:wd="urn:com.workday/bsvc"
    exclude-result-prefixes="xsd op wd"    
    version="2.0">

    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/">      
        <File>            
            <Header separator=",">
                <xsl:call-template name="printHeader"/>
            </Header>            

            <xsl:for-each select="root/wd:Report_Entry">
                <xsl:variable name="cobrarecordcount" as="xsd:integer" select="count(wd:COBRA_Records_within_Range)"/>
                <xsl:variable name="record" select="."/>

                <xsl:for-each select="1 to $cobrarecordcount"> 
                    <xsl:call-template name="printRecord">
                        <xsl:with-param name="record" select="$record"></xsl:with-param>
                    </xsl:call-template>
                </xsl:for-each>                                                         
            </xsl:for-each>             
        </File>         

    </xsl:template>

    <xsl:template name="printHeader">   
        <xsd:element><xsl:text>Employee ID</xsl:text></xsd:element>
        <xsd:element><xsl:text>Employee Last Name</xsl:text></xsd:element>
        <xsd:element><xsl:text>Employee First Name </xsl:text></xsd:element>        
        <xsd:element><xsl:text>Qualifying Event Date</xsl:text></xsd:element>
        <xsd:element><xsl:text>Qualifying Event Type</xsl:text></xsd:element>        
        <xsd:element><xsl:text>Benefit Plan 1</xsl:text></xsd:element>
    </xsl:template> 

    <xsl:template name="printRecord">
        <xsl:param name="record"/>

                <Line separator=","  quoteStyle="double" quoteWhenMatches=".*[a-zA-Z].*">
                    <!--Employee Id-->
                    <xsd:element>
                        <xsl:value-of select="$record/wd:Employee_ID"/>
                    </xsd:element>     
                    <!--Employee Last Name-->
                    <xsd:element>
                        <xsl:value-of select="$record/wd:Employee_Last_Name"/>
                    </xsd:element>      
                    <!--Employee First Name-->
                    <xsd:element>
                        <xsl:value-of select="$record/wd:Employee_First_Name"/>
                    </xsd:element>  
                    <!--Qualifying Event Date-->
                    <xsd:element>
                        <xsl:value-of select="($record/wd:COBRA_Records_within_Range[position()]/wd:Qualifying_Event_Date)"/>
                    </xsd:element> 
                    <!--Qualifying Event Type-->
                    <xsd:element>
                        <xsl:value-of select="($record/wd:COBRA_Records_within_Range[position()]/wd:Eligibility_Reason)"/>
                    </xsd:element> 
                    <!--Benefit-->
                    <xsd:element>
                        <xsl:value-of select="$record/wd:COBRA_Records_within_Range[position()]/wd:Benefit_Plan1"/>
                    </xsd:element> 
                </Line>
    </xsl:template>    
</xsl:stylesheet>

2

xml xpath xslt xslt-2.0 xpath-2.0

Источник

user5656982 10 дек '15 в 15:23

3 ответа

Решение

В предикате для wd:COBRA_Records_within_Range элементы, вы указываете position(), но это не дает вам текущее значение из вашей последовательности в xsl:for-each, position() это позиция узла контекста.

Вы хотите фильтровать только для тех, кто position() равно текущему номеру из вашего xsl:for-each,

Для этого добавьте еще один параметр в шаблон и передайте текущее значение при его вызове:

В приведенном ниже примере я создал параметр с именем rangeIndex и использовал стенографический предикат [$rangeIndex], но мог бы также использовать [position() = $rangeIndex]:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xsd="http://www.w3.org/2001/XMLSchema"
    xmlns:op="http://www.w3.org/2005/xpath-functions"
    xmlns:wd="urn:com.workday/bsvc"
    exclude-result-prefixes="xsd op wd"    
    version="2.0">

    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/">      
        <File>            
            <Header separator=",">
                <xsl:call-template name="printHeader"/>
            </Header>            

            <xsl:for-each select="root/wd:Report_Entry">
                <xsl:variable name="cobrarecordcount" as="xsd:integer" select="count(wd:COBRA_Records_within_Range)"/>
                <xsl:variable name="record" select="."/>

                <xsl:for-each select="1 to $cobrarecordcount"> 
                    <xsl:call-template name="printRecord">
                        <xsl:with-param name="record" select="$record"></xsl:with-param>
                        <xsl:with-param name="rangeIndex" select="."/>
                    </xsl:call-template>
                </xsl:for-each>                                                         
            </xsl:for-each>             
        </File>         

    </xsl:template>

    <xsl:template name="printHeader">   
        <xsd:element><xsl:text>Employee ID</xsl:text></xsd:element>
        <xsd:element><xsl:text>Employee Last Name</xsl:text></xsd:element>
        <xsd:element><xsl:text>Employee First Name </xsl:text></xsd:element>        
        <xsd:element><xsl:text>Qualifying Event Date</xsl:text></xsd:element>
        <xsd:element><xsl:text>Qualifying Event Type</xsl:text></xsd:element>        
        <xsd:element><xsl:text>Benefit Plan 1</xsl:text></xsd:element>
    </xsl:template> 

    <xsl:template name="printRecord">
        <xsl:param name="record"/>
        <xsl:param name="rangeIndex"/>
        <Line separator=","  quoteStyle="double" quoteWhenMatches=".*[a-zA-Z].*">
            <!--Employee Id-->
            <xsd:element>
                <xsl:value-of select="$record/wd:Employee_ID"/>
            </xsd:element>     
            <!--Employee Last Name-->
            <xsd:element>
                <xsl:value-of select="$record/wd:Employee_Last_Name"/>
            </xsd:element>      
            <!--Employee First Name-->
            <xsd:element>
                <xsl:value-of select="$record/wd:Employee_First_Name"/>
            </xsd:element>  
            <!--Qualifying Event Date-->
            <xsd:element>
                <xsl:value-of select="($record/wd:COBRA_Records_within_Range[$rangeIndex]/wd:Qualifying_Event_Date)"/>
            </xsd:element> 
            <!--Qualifying Event Type-->
            <xsd:element>
                <xsl:value-of select="($record/wd:COBRA_Records_within_Range[$rangeIndex]/wd:Eligibility_Reason)"/>
            </xsd:element> 
            <!--Benefit-->
            <xsd:element>
                <xsl:value-of select="$record/wd:COBRA_Records_within_Range[$rangeIndex]/wd:Benefit_Plan1"/>
            </xsd:element> 
        </Line>
    </xsl:template>    
</xsl:stylesheet>

2

Источник

user14419 11 дек '15 в 15:03

Вот гораздо более простое и короткое решение, которое не использует <xsl:for-each> совсем:

I. XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:wd="urn:com.workday/bsvc">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vHeader" 
      select="string-join(/*/*/*[not(self::wd:COBRA_Records_within_Range)], ', ')"/>

  <xsl:template match="wd:COBRA_Records_within_Range">
    <xsl:value-of select="string-join(($vHeader, *), ', '), '&#xA;'"/>
  </xsl:template>
  <xsl:template match="text()"/>
</xsl:stylesheet>

II. XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:wd="urn:com.workday/bsvc">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vHeader">
   <xsl:apply-templates 
        select="/*/*/*[not(self::wd:COBRA_Records_within_Range)]" mode="header"/>
 </xsl:variable>

  <xsl:template match="wd:COBRA_Records_within_Range">
    <xsl:value-of select="$vHeader"/><xsl:text>, </xsl:text>
    <xsl:apply-templates mode="header"/>
    <xsl:value-of select="'&#xA;'"/>
  </xsl:template>

  <xsl:template match="*[text()]" mode="header">
    <xsl:if test="not(position() = 1)">, </xsl:if>
    <xsl:value-of select="."/>
  </xsl:template>
  <xsl:template match="text()"/>
</xsl:stylesheet>

2

Источник

user36305 13 дек '15 в 01:53

Другие вопросы по тегам xml xpath xslt xslt-2.0 xpath-2.0

user3016153 10 дек '15 в 21:11 2015-12-10 21:11 · Accepted Answer · 2015-12-10 21:11

Я не могу найти рифму или причину в вашей попытке XSLT. Ожидаемый результат может быть достигнут очень просто:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:wd="urn:com.workday/bsvc">
<xsl:output method="text" encoding="UTF-8"/>
<xsl:strip-space elements="*"/>

<xsl:template match="wd:Report_Entry">
    <xsl:variable name="common">
        <xsl:value-of select="wd:Employee_ID" />
        <xsl:text>, </xsl:text>
        <xsl:value-of select="wd:Worker" />
        <xsl:text>, </xsl:text>
        <xsl:value-of select="wd:Employee_Last_Name" />
        <xsl:text>, </xsl:text>
        <xsl:value-of select="wd:Employee_First_Name" />
        <xsl:text>, </xsl:text>
    </xsl:variable> 
    <xsl:for-each select="wd:COBRA_Records_within_Range">
        <xsl:copy-of select="$common"/>
        <xsl:value-of select="wd:Qualifying_Event_Date" />
        <xsl:text>, </xsl:text>
        <xsl:value-of select="wd:Eligibility_Reason" />
        <xsl:text>, </xsl:text>
        <xsl:value-of select="wd:Benefit_Plan1" />
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>