Почему десериализованный TDictionary не работает правильно?

Question

Я пытаюсь сериализовать / десериализовать стандартный контейнер Delphi, используя стандартный сериализатор Delphi.

procedure TForm7.TestButtonClick(Sender: TObject);
var
    dict: TDictionary<Integer, Integer>;
    jsonValue: TJSONValue;
begin
    //serialization
    dict := TDictionary<Integer, Integer>.Create;
    dict.Add(1, 1);
    jsonValue := TJsonConverter.ObjectToJSON(dict);
    dict.Free;

    //deserialization
    dict := TJsonConverter.JSONToObject(jsonValue) as TDictionary<Integer, Integer>;
    try
        Assert(dict.ContainsKey(1), 'deserialization error - key not found');
    except
        Assert(false, 'deserialization error - dict object broken');
    end;
end;

Есть способ, которым я конвертирую объект в JSON и наоборот;

class function TJsonConverter.JSONToObject(AJSONValue: TJSONValue): TObject;
var
    lUnMarshal: TJSONUnMarshal;
begin
    lUnMarshal := TJSONUnMarshal.Create();
    try
        Result := lUnMarshal.Unmarshal(AJSONValue);
    finally
        lUnMarshal.Free;
    end;
end;

class function TJsonConverter.ObjectToJSON(AData: TObject): TJSONValue;
var
    lMarshal: TJSONMarshal;
begin
    lMarshal := TJSONMarshal.Create();

    try
        Result := lMarshal.Marshal(AData);
    finally
        lMarshal.Free;
    end;
end;

линия:

dict := TJsonConverter.JSONToObject(jsonValue) as TDictionary<Integer, Integer>;

неправильно создает словарь. Вот как выглядит диктатор, создаваемый конструктором: [

и вот дикт, созданный десериализацией:

Как я могу это исправить?

Редактировать: вот содержание JSON

 {
       "type" : "System.Generics.Collections.TDictionary<System.Integer,System.Integer>",
       "id" : 1,
       "fields" : {
          "FItems" : [
             [ -1, 0, 0 ],
             [ -1, 0, 0 ],
             [ -1, 0, 0 ],
             [ 911574339, 1, 1 ]
          ],
          "FCount" : 1,
          "FGrowThreshold" : 3,
          "FKeyCollection" : null,
          "FValueCollection" : null
       }
    }

Answer 1

Проблема в том, что TJSONMarshal создание словаря с использованием RTTI. Он делает это, вызывая первый беспараметрический конструктор, который он может найти. И, к сожалению, это конструктор, определенный в TObject,

Давайте посмотрим на конструкторы, объявленные в TDictionary<K,V>, Они есть, по крайней мере, в моей версии XE7:

constructor Create(ACapacity: Integer = 0); overload;
constructor Create(const AComparer: IEqualityComparer<TKey>); overload;
constructor Create(ACapacity: Integer; const AComparer: IEqualityComparer<TKey>); overload;
constructor Create(const Collection: TEnumerable<TPair<TKey,TValue>>); overload;
constructor Create(const Collection: TEnumerable<TPair<TKey,TValue>>; 
  const AComparer: IEqualityComparer<TKey>); overload;

Все эти конструкторы имеют параметры.

Не обманывайтесь тем, что вы пишете

TDictionary<Integer, Integer>.Create

и создать экземпляр с FComparer назначены. Это разрешает первую перегрузку выше, и поэтому компилятор переписывает этот код как

TDictionary<Integer, Integer>.Create(0)

заполнив параметр по умолчанию.

Что вам нужно сделать, так это убедиться, что вы используете только те классы, которые имеют конструкторы без параметров, которые правильно создают экземпляр класса. к несчастью TDictionary<K,V> не соответствует требованиям.

Однако вы можете получить подкласс, который представляет конструктор без параметров, и ваш код должен работать с этим классом.

Следующий код демонстрирует:

{$APPTYPE CONSOLE}

uses
  System.SysUtils,
  System.Generics.Collections,
  System.Rtti;

type
  TDictionary<K,V> = class(System.Generics.Collections.TDictionary<K,V>)
  public
    constructor Create;
  end;

{ TDictionary<K, V> }

constructor TDictionary<K, V>.Create;
begin
  inherited Create(0);
end;

type
  TInstance<T: class> = class
    class function Create: T; static;
  end;

class function TInstance<T>.Create: T;
// mimic the way that your JSON marshalling code instantiates objects
var
  ctx: TRttiContext;
  typ: TRttiType;
  mtd: TRttiMethod;
  cls: TClass;
begin
  typ := ctx.GetType(TypeInfo(T));
  for mtd in typ.GetMethods do begin
    if mtd.HasExtendedInfo and mtd.IsConstructor then
    begin
      if Length(mtd.GetParameters) = 0 then
      begin
        cls := typ.AsInstance.MetaclassType;
        Result := mtd.Invoke(cls, []).AsType<T>;
        exit;
      end;
    end;
  end;
  Result := nil;
end;

var
  Dict: TDictionary<Integer, Integer>;

begin
  Dict := TInstance<TDictionary<Integer, Integer>>.Create;
  Dict.Add(0, 0);
  Writeln(BoolToStr(Dict.ContainsKey(0), True));
  Readln;
end.