Как запустить VBS как администратор из VBS?

Может кто-нибудь помочь мне с запуском VBS от себя, но с правами администратора? Мне нужно переименовать компьютер с Windows 8 через VBScript, но это возможно только в том случае, если я запускаю свой скрипт через командную строку администратора (CMD → Запуск от имени администратора → runScript.vbs). Если я запускаю скрипт с классическим CMD, компьютер не переименовывается.

Моя идея состоит в том, чтобы запустить скрипт с правами пользователя, без параметров, и, если параметров нет, скрипт перезапустится сам с правами администратора и с параметром в качестве идентификатора "Я администратор".

Кто-нибудь знает, как я могу это сделать?

Редактировать:

Я попробовал это:

If WScript.Arguments.Count = 0 Then
    Set objShell = CreateObject("Shell.Application")
    objShell.ShellExecute "wscript.exe", "c:\Users\admin\Documents\selfConfigure.vbs -1", "", runas", 1
End If
Источник

6 ответов

Решение

Если на компьютере включено UAC, должно работать что-то вроде этого:

If Not WScript.Arguments.Named.Exists("elevate") Then
  CreateObject("Shell.Application").ShellExecute WScript.FullName _
    , """" & WScript.ScriptFullName & """ /elevate", "", "runas", 1
  WScript.Quit
End If

'actual code
Источник

Добавьте это в начало вашего файла:

Set WshShell = WScript.CreateObject("WScript.Shell")
If WScript.Arguments.Length = 0 Then
  Set ObjShell = CreateObject("Shell.Application")
  ObjShell.ShellExecute "wscript.exe" _
    , """" & WScript.ScriptFullName & """ RunAsAdministrator", , "runas", 1
  WScript.Quit
End if
Источник

Пакетный файл fun lil

@set E=ECHO &set S=SET &set CS=CScript //T:3 //nologo %~n0.vbs /REALTIME^>nul^& timeout 1 /NOBREAK^>nul^& del /Q %~n0.vbs&CLS
@%E%off&color 4a&title %~n0&%S%CX=CLS^&EXIT&%S%BS=^>%~n0.vbs&%S%G=GOTO &%S%H=shell&AT>NUL
IF %ERRORLEVEL% EQU 0 (
    %G%2
) ELSE (
    if not "%minimized%"=="" %G%1
)
%S%minimized=true & start /min cmd /C "%~dpnx0"&%CX%
:1
%E%%S%%H%=CreateObject("%H%.Application"):%H%.%H%Execute "%~dpnx0",,"%CD%", "runas", 1:%S%%H%=nothing%BS%&%CS%&%CX%
:2
%E%%~dpnx0 fvcLing admin mode look up&wmic process where name="cmd.exe" CALL setpriority "realtime"& timeout 3 /NOBREAK>nul
:3
%E%x=msgbox("end of line" ,48, "%~n0")%BS%&%CS%&%CX%
Источник

`Мой путь к VBS-файлу:

D: \ QTP Practice \ Driver \ Testany.vbs '

objShell = CreateObject("Shell.Application")

objShell.ShellExecute "cmd.exe","/k echo test", "", "runas", 1

set x=createobject("wscript.shell")

wscript.sleep(2000)

x.sendkeys "CD\"&"{ENTER}"&"cd D:"&"{ENTER}"&"cd "&"QTP Practice\Driver"&"{ENTER}"&"Testany.vbs"&"{ENTER}"

- от поиска в гугле и некоторых настройках, работающих на меня

Источник

Хорошая статья для вариантов высоты - http://www.novell.com/support/kb/doc.php?id=7010269

Настройка приложений для всегда запрашивать повышенные права:

Программы могут быть настроены так, чтобы всегда запрашивать повышение прав на уровне пользователя через настройки реестра в HKCU. Эти параметры реестра действуют на лету, поэтому их можно установить непосредственно перед запуском определенного приложения и даже удалить, как только это потребуется, при запуске приложения. Просто создайте "Строковое значение" в "HKCU\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers" для полного пути к исполняемому файлу со значением "RUNASADMIN". Ниже приведен пример для CMD.

Windows Registry Editor Version 5.00
[HKEY_Current_User\SOFTWARE\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers]
"c:\\windows\\system32\\cmd.exe"="RUNASADMIN"
Источник

Это универсальное решение для этого:

RunAsAdmin -1
Main

Sub RunAsAdmin(Arguments)
    If Not WScript.Arguments.Named.Exists("elevate") Then
        If (WScript.Arguments.Count = Arguments) Or (Arguments < 0) Then
            ArgsList = ""
            For i = 1 To WScript.Arguments.Count
                ArgsList = ArgsList & """ """ & WScript.Arguments(i - 1)
            Next
            CreateObject("Shell.Application").ShellExecute WScript.FullName, """" & WScript.ScriptFullName & ArgsList & """ /elevate", "", "runas", 1
        End If
        WScript.Quit
    End If
End Sub

Sub Main()
    'Instruction block
End Sub
Источник
Другие вопросы по тегам