Рассчитать прошедшее время во вспышке

Question

Я строю тест, и мне нужно рассчитать общее время, необходимое для проведения теста. и мне нужно отобразить время, занятое в HH::MM::SS.. какие-либо указатели?

Answer 1

new Date().time возвращает время в миллисекундах.

var nStart:Number = new Date().time;

// Some time passes

var nMillisElapsed:Number = new Date().time - nStart;

var strTime:String = Math.floor(nMillisElapsed / (1000 * 60 * 60)) + "::" + 
   (Math.floor(nMillisElapsed / (1000 * 60)) % 60) + "::" + 
   (Math.floor(nMillisElapsed / (1000)) % 60);

Answer 2

Я воскрешаю этот вопрос, чтобы сказать, что и Брайан, и Слюда ошибаются. Создание новой даты () дает вам время в соответствии с часами компьютера. Все, что нужно сделать, - это установить часы на несколько минут назад, и таймер викторины тоже вернется на несколько минут назад. Или, что еще хуже, они могли установить часы на время, предшествующее началу теста, и ваше приложение будет считать, что они потратили немало времени на его проведение. оо

Решением является использование flash.utils.getTimer(). Возвращает количество миллисекунд с момента начала воспроизведения SWF независимо от того, что показывают часы компьютера.

Вот пример:

var startTime:Number = getTimer();

// then after some time passes:

var elapsedMilliseconds:Number = getTimer() - startTime;

Затем вы можете использовать код Брайана, чтобы отформатировать время для отображения:

var strTime:String = Math.floor(elapsedMilliseconds / (1000 * 60 * 60)) + "::" + 
(Math.floor(elapsedMilliseconds / (1000 * 60)) % 60) + "::" + 
(Math.floor(elapsedMilliseconds / (1000)) % 60);

Answer 3

Заполните ноль, когда число меньше 10 (Спасибо, Брайан)

var now:Date; //
var startDate:Date;
var startTime:Number; 
// initialize timer and start it
function initTimer():void{
    startDate = new Date();
    startTime = startDate.getTime();
    //
    var timer:Timer = new Timer(1000,0); // set a new break
        timer.addEventListener(TimerEvent.TIMER, onTimer); // add timer listener
    //
    function onTimer():void{
        now=new Date();
        var nowTime:Number = now.getTime();
        var diff:Number = nowTime-startTime;
        var strTime:String = Math.floor(diff / (1000 * 60 * 60)) + ":" + 
                            zeroFill(Math.floor(diff / (1000 * 60)) % 60) + ":" + 
                            zeroFill(Math.floor(diff / (1000)) % 60);
        // display where you want
        trace('time elapsed : ' + strTime);
    }
    // fill with zero when number is less than 10
    function zeroFill(myNumber:Number):String{
        var zeroFilledNumber:String=myNumber.toString();
        if(myNumber<10){
            zeroFilledNumber = '0'+zeroFilledNumber;
        }
        return zeroFilledNumber;
    }

    // start TIMER
    timer.start();

}
initTimer();

Answer 4

var countdown:Timer = new Timer(1000);
countdown.addEventListener(TimerEvent.TIMER, timerHandler);
countdown.start();

function timerHandler(e:TimerEvent):void
{           
    var minute = Math.floor(countdown.currentCount /  60);
    if(minute < 10)
        minute = '0'+minute;

    var second = countdown.currentCount % 60;
    if(second < 10)
        second = '0'+second;


    var timeElapsed = minute +':'+second;
    trace(timeElapsed);
}