Подсветка строки режима Emacs во время определения макроса

Question

Есть ли такой простой способ иметь четкий индикатор, когда я определяю макрос клавиатуры (kmacro-start-macro-or-insert-counter), например, путем изменения фона строки режима или чего-то подобного?

Индикатор "Def" трудно разобрать, а иногда и не видно из-за большого количества индикаторов второстепенного режима / узкого экрана.

Большое спасибо!

Answer 1

Я использовал стандартные функции, связанные с f3 а также f4 и изменил их, добавив my-modeline-face-functionи отзовите эти ключи к новым функциям. Вы можете изменить цвет лица в my-modeline-face-function чтобы удовлетворить ваши потребности. Я решил использовать cond потому что вы можете обнаружить, что у вас есть другие аналогичные потребности для различных основных и второстепенных режимов, и вы можете вставить аналогичные условия для этих режимов. [Например, вы можете сделать это для режима isearch, или калькулятора, и т. Д.]

Значение, возвращаемое face-remap-add-relative хранится в пользовательской переменной, которую я назвал my-face-remap-cookieкоторый, в свою очередь, используется в конце фазы записи макроса в качестве аргумента функции face-remap-remove-relative,

(defun my-kmacro-start-macro-or-insert-counter (arg)
  "Record subsequent keyboard input, defining a keyboard macro.
The commands are recorded even as they are executed.

Sets the `kmacro-counter' to ARG (or 0 if no prefix arg) before defining the
macro.

With \\[universal-argument], appends to current keyboard macro (keeping
the current value of `kmacro-counter').

When defining/executing macro, inserts macro counter and increments
the counter with ARG or 1 if missing.  With \\[universal-argument],
inserts previous `kmacro-counter' (but do not modify counter).

The macro counter can be modified via \\[kmacro-set-counter] and \\[kmacro-add-counter].
The format of the counter can be modified via \\[kmacro-set-format]."
  (interactive "P")
  (if (or defining-kbd-macro executing-kbd-macro)
      (progn
        (my-modeline-face-function)
        (kmacro-insert-counter arg))
    (kmacro-start-macro arg)
    (my-modeline-face-function)))

(defun my-kmacro-end-or-call-macro (arg &optional no-repeat)
  "End kbd macro if currently being defined; else call last kbd macro.
With numeric prefix ARG, repeat macro that many times.
With \\[universal-argument], call second macro in macro ring."
  (interactive "P")
  (cond
   (defining-kbd-macro
     (if kmacro-call-repeat-key
   (kmacro-call-macro arg no-repeat t)
       (kmacro-end-macro arg)))
   ((and (eq this-command 'kmacro-view-macro)  ;; We are in repeat mode!
   kmacro-view-last-item)
    (kmacro-exec-ring-item (car kmacro-view-last-item) arg))
   ((and arg (listp arg))
    (kmacro-call-ring-2nd 1))
   (t
    (kmacro-call-macro arg no-repeat)))
  (my-modeline-face-function))

(defface my-recording-macro-face
  '((t (:background "yellow" :foreground "black")))
  "Face for `my-recording-macro-face`."
  :group 'my-faces)

(defvar my-face-remap-cookie nil
"The return value of `face-remap-add-relative` is a Lisp object that
serves as a `cookie`; you can pass this object as an argument to
`face-remap-remove-relative` if you need to remove the remapping later.")
(make-variable-buffer-local 'my-face-remap-cookie)

(defun my-modeline-face-function ()
"Doc-string."
  (require 'face-remap)
  (cond
    (defining-kbd-macro
      (setq my-face-remap-cookie
        (face-remap-add-relative 'mode-line 'my-recording-macro-face)))
    (t
      (face-remap-remove-relative my-face-remap-cookie)
      (setq my-face-remap-cookie nil))))

(define-key global-map [f3] 'my-kmacro-start-macro-or-insert-counter)

(define-key global-map [f4] 'my-kmacro-end-or-call-macro)

Answer 2

(setq minor-mode-alist
      `((abbrev-mode " Abbrev")
        (overwrite-mode overwrite-mode)
        (auto-fill-function " Fill")
        ;; not really a minor mode...
        (defining-kbd-macro ,(propertize " Def" 'face 'highlight))))

Все, что я сделал, это подправил оригинальный код bindings.el, заменяя " Def" со значением (propertize " Def" 'face 'highlight),

Используйте любое лицо или спецификацию лица, которые вам нравятся, вместо highlight,