Заголовки TLabel и TGroupbox мерцают при изменении размера

Question

• Итак, у меня есть приложение, которое загружает различные плагины и создает новую вкладку в TPageControl для каждого.
• С каждой DLL связана TForm.
• Формы создаются с их родительским hWnd как новый TTabSheet.

• Поскольку TTabSheets не является родительским для формы в том, что касается VCL (яне хотел использовать динамический RTL и плагины, сделанные на других языках), мне приходится обрабатывать изменения размера вручную. Я делаю это, как показано ниже:

  var
    ChildHandle : DWORD;
  begin
    If Assigned(pcMain.ActivePage) Then
      begin
      ChildHandle := FindWindowEx(pcMain.ActivePage.Handle, 0, 'TfrmPluginForm', nil);
      If ChildHandle > 0 Then
        begin
        SetWindowPos(ChildHandle, 0, 0, 0, pcMain.ActivePage.Width, pcMain.ActivePage.Height, SWP_NOZORDER + SWP_NOACTIVATE + SWP_NOCOPYBITS);
      end;
    end;
  

Теперь моя проблема заключается в том, что при изменении размера приложения все TGroupBoxes и TLabels внутри TGroupBoxes мерцают. TLabels, которые не находятся внутри TGroupboxes, хороши и не мерцают.

Вещи, которые я пробовал:

• WM_SETREDRAW, за которым следует RedrawWindow
• ParentBackground для TGroupBoxes и TLabels установлено в False
• DoubleBuffer:= True
• LockWindowUpdate (да, хотя я знаю, что это очень, очень неправильно)
• Прозрачный:= Ложь (даже переопределение создания для редактирования ControlState)

Есть идеи?

Answer 1

Единственное, что я нашел, чтобы работать хорошо, это использовать WS_EX_COMPOSITED стиль окна Это снижение производительности, поэтому я включаю его только в цикле калибровки. По моему опыту, благодаря встроенным элементам управления в моем приложении мерцание возникает только при изменении размеров форм.

Сначала вы должны выполнить быстрый тест, чтобы увидеть, поможет ли этот подход, просто добавив WS_EX_COMPOSITED стиль окна для всех ваших оконных элементов управления. Если это работает, вы можете рассмотреть более продвинутый подход ниже:

Быстрый взлом

procedure EnableComposited(WinControl: TWinControl);
var
  i: Integer;
  NewExStyle: DWORD;
begin
  NewExStyle := GetWindowLong(WinControl.Handle, GWL_EXSTYLE) or WS_EX_COMPOSITED;
  SetWindowLong(WinControl.Handle, GWL_EXSTYLE, NewExStyle);

  for i := 0 to WinControl.ControlCount-1 do
    if WinControl.Controls[i] is TWinControl then
      EnableComposited(TWinControl(WinControl.Controls[i]));
end;

Назовите это, например, в OnShow для тебя TForm, передавая экземпляр формы. Если это поможет, тогда вы действительно должны реализовать это более проницательно. Я даю вам соответствующие выдержки из моего кода, чтобы проиллюстрировать, как я это сделал.

Полный код

procedure TMyForm.WMEnterSizeMove(var Message: TMessage);
begin
  inherited;
  BeginSizing;
end;

procedure TMyForm.WMExitSizeMove(var Message: TMessage);
begin
  EndSizing;
  inherited;
end;

procedure SetComposited(WinControl: TWinControl; Value: Boolean);
var
  ExStyle, NewExStyle: DWORD;
begin
  ExStyle := GetWindowLong(WinControl.Handle, GWL_EXSTYLE);
  if Value then begin
    NewExStyle := ExStyle or WS_EX_COMPOSITED;
  end else begin
    NewExStyle := ExStyle and not WS_EX_COMPOSITED;
  end;
  if NewExStyle<>ExStyle then begin
    SetWindowLong(WinControl.Handle, GWL_EXSTYLE, NewExStyle);
  end;
end;

function TMyForm.SizingCompositionIsPerformed: Boolean;
begin
  //see The Old New Thing, Taxes: Remote Desktop Connection and painting
  Result := not InRemoteSession;
end;
procedure TMyForm.BeginSizing;
var
  UseCompositedWindowStyleExclusively: Boolean;
  Control: TControl;
  WinControl: TWinControl;
begin
  if SizingCompositionIsPerformed then begin
    UseCompositedWindowStyleExclusively := Win32MajorVersion>=6;//XP can't handle too many windows with WS_EX_COMPOSITED
    for Control in ControlEnumerator(TWinControl) do begin
      WinControl := TWinControl(Control);
      if UseCompositedWindowStyleExclusively then begin
        SetComposited(WinControl, True);
      end else begin
        if WinControl is TPanel then begin
          TPanel(WinControl).FullRepaint := False;
        end;
        if (WinControl is TCustomGroupBox) or (WinControl is TCustomRadioGroup) or (WinControl is TCustomGrid) then begin
          //can't find another way to make these awkward customers stop flickering
          SetComposited(WinControl, True);
        end else if ControlSupportsDoubleBuffered(WinControl) then begin
          WinControl.DoubleBuffered := True;
        end;
      end;
    end;
  end;
end;

procedure TMyForm.EndSizing;
var
  Control: TControl;
  WinControl: TWinControl;
begin
  if SizingCompositionIsPerformed then begin
    for Control in ControlEnumerator(TWinControl) do begin
      WinControl := TWinControl(Control);
      if WinControl is TPanel then begin
        TPanel(WinControl).FullRepaint := True;
      end;
      UpdateDoubleBuffered(WinControl);
      SetComposited(WinControl, False);
    end;
  end;
end;

function TMyForm.ControlSupportsDoubleBuffered(Control: TWinControl): Boolean;
const
  NotSupportedClasses: array [0..1] of TControlClass = (
    TCustomForm,//general policy is not to double buffer forms
    TCustomRichEdit//simply fails to draw if double buffered
  );
var
  i: Integer;
begin
  for i := low(NotSupportedClasses) to high(NotSupportedClasses) do begin
    if Control is NotSupportedClasses[i] then begin
      Result := False;
      exit;
    end;
  end;
  Result := True;
end;

procedure TMyForm.UpdateDoubleBuffered(Control: TWinControl);

  function ControlIsDoubleBuffered: Boolean;
  const
    DoubleBufferedClasses: array [0..2] of TControlClass = (
      TMyCustomGrid,//flickers when updating
      TCustomListView,//flickers when updating
      TCustomStatusBar//drawing infidelities , e.g. my main form status bar during file loading
    );
  var
    i: Integer;
  begin
    if not InRemoteSession then begin
      //see The Old New Thing, Taxes: Remote Desktop Connection and painting
      for i := low(DoubleBufferedClasses) to high(DoubleBufferedClasses) do begin
        if Control is DoubleBufferedClasses[i] then begin
          Result := True;
          exit;
        end;
      end;
    end;
    Result := False;
  end;

var
  DoubleBuffered: Boolean;

begin
  if ControlSupportsDoubleBuffered(Control) then begin
    DoubleBuffered := ControlIsDoubleBuffered;
  end else begin
    DoubleBuffered := False;
  end;
  Control.DoubleBuffered := DoubleBuffered;
end;

procedure TMyForm.UpdateDoubleBuffered;
var
  Control: TControl;
begin
  for Control in ControlEnumerator(TWinControl) do begin
    UpdateDoubleBuffered(TWinControl(Control));
  end;
end;

Это не скомпилируется для вас, но должно содержать некоторые полезные идеи. ControlEnumerator моя утилита, чтобы превратить рекурсивную прогулку дочерних элементов управления в квартиру for петля. Обратите внимание, что я также использую собственный сплиттер, который вызывает BeginSizing/EndSizing, когда он активен.

Еще один полезный трюк заключается в использовании TStaticText вместо TLabel что вам иногда нужно делать, когда у вас есть глубокие вложения элементов управления страниц и панелей.

Я использовал этот код, чтобы сделать мое приложение без мерцания на 100%, но мне потребовались годы и годы экспериментов, чтобы все это было на месте. Надеюсь, что другие могут найти что-то полезное здесь.

Answer 2

Используйте VCL Fix Pack от Андреаса Хаусладена.

Дополнительно: не указывайте SWP_NOCOPYBITS флаг и установить DoubleBuffered PageControl:

uses
  VCLFixPack;

procedure TForm1.FormCreate(Sender: TObject);
begin
  PageControl1.DoubleBuffered := True;

  //Setup test conditions:
  FForm2 := TForm2.Create(Self);
  FForm2.BorderStyle := bsNone;
  FForm2.BoundsRect := TabSheet1.ClientRect;
  Windows.SetParent(FForm2.Handle, TabSheet1.Handle);
  FForm2.Show;
  PageControl1.Anchors := [akLeft, akTop, akRight, akBottom];
  PageControl1.OnResize := PageControl1Resize;
end;

procedure TForm1.PageControl1Resize(Sender: TObject);
begin
  SetWindowPos(FForm2.Handle, 0, 0, 0, TabSheet1.ClientWidth,
    TabSheet1.ClientHeight, SWP_NOZORDER + SWP_NOACTIVATE);
end;

Answer 3

Это решение, которое я с успехом использую в своем проекте в различных формах. Это немного грязно, потому что он использует функции winapi. По сравнению с ответом Дэвида это не включает в себя снижение производительности. Смысл в том, чтобы переписать обработчик сообщения для сообщения WM_ERASEBKGND для формы и всех ее дочерних окон.

typedef LRESULT CALLBACK(*PWndProc)(HWND, UINT, WPARAM, LPARAM);

void SetNonFlickeringWndProc(TWinControl &control, std::map<HWND,PWndProc> &list, PWndProc new_proc)
{
   if (control.Handle == 0)
   {
      return;
   }

   PWndProc oldWndProc = (PWndProc)SetWindowLong(control.Handle, GWL_WNDPROC, (LONG)new_proc);
   list[control.Handle] = oldWndProc;

   int count = control.ControlCount;
   for (int i = 0; i < count; i++)
   {
      TControl *child_control = control.Controls[i];
      TWinControl *child_wnd_control = dynamic_cast<TWinControl*>(child_control);
      if (child_wnd_control == NULL)
      {
         continue;
      }

      SetNonFlickeringWndProc(*child_wnd_control, list, new_proc);
   }
}

void RestoreWndProc(std::map<HWND,PWndProc> &old_wnd_proc)
{
   std::map<HWND,PWndProc>::iterator it;
   for (it = old_wnd_proc.begin(); it != old_wnd_proc.end(); it++)
   {
      LONG res = SetWindowLong(it->first, GWL_WNDPROC, (LONG)it->second);
   }
   old_wnd_proc.clear();
}

std::map<HWND,PWndProc> oldwndproc;   // addresses for window procedures for all components in form

LRESULT CALLBACK NonFlickeringWndProc(HWND hwnd, UINT uMsg, WPARAM wParam, LPARAM lParam)
{
    if (uMsg == WM_ERASEBKGND)
    {
        return 1;
    }
    return ((PWndProc)oldwndproc[hwnd])(hwnd, uMsg, wParam, lParam);
}

void __fastcall TForm1::FormShow(TObject *Sender)
{
   oldwndproc.clear();
   SetNonFlickeringWndProc(*this, oldwndproc, &NonFlickeringWndProc);
}

void __fastcall TForm1::FormClose(TObject* Sender, TCloseAction& Action)
{
   RestoreWndProc(oldwndproc_etype);
}

Важное примечание: свойство DoubleBufferd для формы должно быть установлено, если вы не хотите видеть черные полосы по бокам!

Answer 4

Поместите над своей формой (интерфейсом) или поместите все это в новый последний блок, включающий:

TLabel = class( stdCtrls.TLabel )
  protected
   procedure WMEraseBkgnd(var Message: TWmEraseBkgnd); message WM_ERASEBKGND;
  end;

Поместите это в часть реализации

procedure TLabel.WMEraseBkgnd(var Message: TWmEraseBkgnd);
begin
 Message.Result:=1; // Fake erase
end;

повторите этот шаг для TGroupBox