Hunchentoot: Почему я не могу получить значение сеанса?

Не совсем CL и не специалист по веб-программированию, поэтому, может быть, я упускаю что-то действительно очевидное: я пытаюсь установить значение сеанса на странице-1 и получить результат на странице-2. Ничего не отображается на странице-2, хотя...

(ql:quickload "cl-who")
(ql:quickload "hunchentoot")

(defpackage :sessmin
  (:use :cl :cl-who :hunchentoot))

(in-package :sessmin)

(defun start-server (port)
  (start (make-instance 'easy-acceptor :port port)))

(setf (html-mode) :html5)

(define-easy-handler (page1 :uri "/page1") ()
  (start-session)
  (setf (session-value :sv) "testvalue")
  (with-html-output-to-string
      (*standard-output* nil :prologue t :indent t)
    (:html :lang "en"
       (:head 
        (:meta :charset "utf-8")
        (:title "page1"))
       (:body 
         (:p "Session Page 1")
         (:p "Go to next page" (:a :href "page2" "here"))))))

(define-easy-handler (page2 :uri "/page2") ()
  (with-html-output-to-string
      (*standard-output* nil :prologue t :indent t)
    (:html :lang "en"
       (:head 
        (:meta :charset "utf-8")
        (:title "page2"))
       (:body 
         (:p "Session Page 2")
         (:p "Session Page 2, value:" (session-value :sv))))))

(start-server 8080)

РЕДАКТИРОВАТЬ: получил "(" неправильно в моей первой версии, все еще не работает после исправления, хотя...

Источник

2 ответа

Решение

Ваша проблема не в том, что значение сеанса не задано, а в формате cl-who.

(:p "Session Page 2, value:" (session-value :sv))

не будет печатать значение сеанса; возвращаемое значение session-value просто игнорируется.

;; try this:
(:p "Session Page 2, value:" (str (session-value :sv)))
;; or, if you need to html-escape the value,
(:p "Session Page 2, value:" (esc (session-value :sv)))
Источник

Не эксперт Hunchentoot, но я думаю, что вы забыли закрыть :head,

Источник
Другие вопросы по тегам