cmake и libpthread

Question

Я бегу RHEL 5.1 и использовать gcc,

Как я говорю cmake добавить -pthread к компиляции и компоновке?

Answer 1

@ Мануэль был частью пути туда. Вы также можете добавить опцию компилятора, например так:

Если у вас CMake 3.1.0+, это станет еще проще:

set(THREADS_PREFER_PTHREAD_FLAG ON)
find_package(Threads REQUIRED)
target_link_libraries(my_app Threads::Threads)

Если вы используете CMake 2.8.12+, вы можете упростить это до:

find_package(Threads REQUIRED)
if(THREADS_HAVE_PTHREAD_ARG)
  target_compile_options(my_app PUBLIC "-pthread")
endif()
if(CMAKE_THREAD_LIBS_INIT)
  target_link_libraries(my_app "${CMAKE_THREAD_LIBS_INIT}")
endif()

Старые версии CMake могут потребовать:

find_package(Threads REQUIRED)
if(THREADS_HAVE_PTHREAD_ARG)
  set_property(TARGET my_app PROPERTY COMPILE_OPTIONS "-pthread")
  set_property(TARGET my_app PROPERTY INTERFACE_COMPILE_OPTIONS "-pthread")
endif()
if(CMAKE_THREAD_LIBS_INIT)
  target_link_libraries(my_app "${CMAKE_THREAD_LIBS_INIT}")
endif()

Если вы хотите использовать один из первых двух методов с CMake 3.1+, вам понадобится set(THREADS_PREFER_PTHREAD_FLAG ON) там тоже.

Answer 2

Следующее должно быть чистым (используя find_package) и работа (модуль поиска называется FindThreads):

cmake_minimum_required (VERSION 2.6) 
find_package (Threads)
add_executable (myapp main.cpp ...)
target_link_libraries (myapp ${CMAKE_THREAD_LIBS_INIT})

Answer 3

Вот правильный ответ:

ADD_EXECUTABLE(your_executable ${source_files})

TARGET_LINK_LIBRARIES( your_executable
pthread
)

эквивалентно

-lpthread

Answer 4

target_compile_optionsрешение выше неверно, оно не свяжет библиотеку.

Использовать:

SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -pthread")

ИЛИ ЖЕ

target_link_libraries(XXX PUBLIC pthread)

ИЛИ ЖЕ

set_target_properties(XXX PROPERTIES LINK_LIBRARIES -pthread)