XSLT: передать переменную в шаблон при использовании apply-templates

Question

Я не уверен, что это слишком много требует XSLT, но я после чего-то похожего mode работает, за исключением идеального внутри одного шаблона, вместо того, чтобы дублировать его, как я сейчас:

<!-- Start -->
<xsl:apply-templates select="airports/airport" mode="start" />

<!-- End -->
<xsl:apply-templates select="airports/airport" mode="end" />

<!-- Template -->
<xsl:template match="airports/airport" mode="start">
    <option value="{@iata}" data-alternative-spellings="{.},{@iata}">
        <xsl:if test="@iata = 'LGW'">
            <xsl:attribute name="selected">selected</xsl:attribute>
        </xsl:if>
        <xsl:value-of select="@iata"/> - <xsl:value-of select="."/>
    </option>
</xsl:template>
<xsl:template match="airports/airport" mode="end">
    <option value="{@iata}" data-alternative-spellings="{.},{@iata}">
        <xsl:if test="@iata = 'LAX'">
            <xsl:attribute name="selected">selected</xsl:attribute>
        </xsl:if>
        <xsl:value-of select="@iata"/> - <xsl:value-of select="."/>
    </option>
</xsl:template>

Шаблон применяет selected атрибут, если значение является чем-то конкретным. Это значение должно быть различным в зависимости от того, что вызывает шаблон. Есть два случая, start а также end что оба имеют разные критерии.

Самый простой способ объяснить, что я пытаюсь сделать, это написать это на другом языке:)

<!-- Start -->
getAirports(start);

<!-- End -->
getAirports(end);

<!-- Template -->
var getAirports = function(position)
{
    var selected = '';
    switch(position)
    {
        case 'start':
            if(iata == 'LGW')
            {
                var selected = 'selected="selected"';
            }
        break;
        case 'end':
            if(iata == 'LAX')
            {
                var selected = 'selected="selected"';
            }
        break;
        default:
        break;
    }
    return '<option value="'+iata+'" data-alternative-spellings="'+iata+','+name+'" '+selected+'>'+iata+' - '+name+'</option>';
}

Это возможно в xslt, или мне придется придерживаться дублирования шаблона и использования mode?

Спасибо!

Answer 1

Один из пользователей Twitter дал мне решение, которое можно найти в этом Gist.

Что мне нужно было with-param, то, что я никогда не использовал раньше:

<!-- Start -->
<xsl:apply-templates select="airports/airport">
    <xsl:with-param name="position" select="'start'" />
</xsl:apply-templates>

<!-- End -->
<xsl:apply-templates select="airports/airport">
    <xsl:with-param name="position" select="'end'" />
</xsl:apply-templates>

<xsl:template match="airports/airport">
    <xsl:param name="position" />
    <option value="{@iata}" data-alternative-spellings="{.},{@iata}">
        <xsl:if test="(@iata = 'LGW' and $position = 'start') or (@iata = 'LAX' and $position = 'end')">
            <xsl:attribute name="selected">selected</xsl:attribute>
        </xsl:if>
        <xsl:value-of select="@iata"/> - <xsl:value-of select="." />
    </option>
</xsl:template>