Функции с универсальными типами параметров

Question

Я пытаюсь выяснить, как определить функцию, которая работает с несколькими типами параметров (например, int и int64). Насколько я понимаю, перегрузка функций невозможна в F# (конечно, компилятор жалуется). Возьмем для примера следующую функцию.

let sqrt_int = function
    | n:int   -> int (sqrt (float n))
    | n:int64 -> int64 (sqrt (float n))

Компилятор, конечно, жалуется, что синтаксис недопустим (ограничения типов в сопоставлении с образцом, похоже, не поддерживаются), хотя я думаю, что это иллюстрирует то, чего я хотел бы достичь: функцию, которая работает с несколькими типами параметров и возвращает значение соответствующего тип. У меня есть ощущение, что это возможно в F#, используя некоторую комбинацию общих типов / вывод типов / сопоставление с образцом, но синтаксис ускользнул от меня. Я также пытался использовать:? оператор (тесты динамического типа) и операторы when в блоке сопоставления с образцом, но это все равно приводит к ошибкам всех видов.

Поскольку я довольно плохо знаком с языком, я вполне могу попытаться сделать что-то невозможное здесь, поэтому, пожалуйста, дайте мне знать, если есть альтернативное решение.

Answer 1

Перегрузка, как правило, является ошибкой в ​​типизированных языках (по крайней мере, когда, как и в F#, система типов недостаточно мощна, чтобы содержать классы типов). В F# у вас есть несколько вариантов:

• Используйте перегрузку для методов (членов типа), в этом случае перегрузка работает так же, как и в других языках.Net (вы можете использовать специальные элементы перегрузки, при условии, что вызовы можно отличить по количеству / типу параметров)
• Используйте "inline", "^" и статические ограничения членов для специальной перегрузки функций (это то, что большинство математических операторов, которые должны работать с int/float/ и т.д.; здесь синтаксис странный, это мало используется кроме библиотеки F#)
• Имитируйте классы типов, передавая дополнительный параметр словаря операций (это то, что INumeric делает в одной из библиотек F# PowerPack для обобщения различных математических алгоритмов для произвольных пользовательских типов)
• Вернитесь к динамической типизации (передайте параметр 'obj', выполните тест динамического типа, сгенерируйте исключение времени выполнения для неверного типа)

Для вашего конкретного примера я бы, вероятно, просто использовал перегрузку метода:

type MathOps =
    static member sqrt_int(x:int) = x |> float |> sqrt |> int
    static member sqrt_int(x:int64) = x |> float |> sqrt |> int64

let x = MathOps.sqrt_int 9
let y = MathOps.sqrt_int 100L

Answer 2

Это работает:

type T = T with
    static member ($) (T, n:int  ) = int   (sqrt (float n))
    static member ($) (T, n:int64) = int64 (sqrt (float n))

let inline sqrt_int (x:'t) :'t = T $ x

Он использует статические ограничения и перегрузку, что делает поиск во время компиляции по типу аргумента.

Статические ограничения автоматически генерируются в присутствии оператора (оператора $ в данном случае) но это всегда можно написать от руки:

type T = T with
    static member Sqr (T, n:int  ) = int   (sqrt (float n))
    static member Sqr (T, n:int64) = int64 (sqrt (float n))

let inline sqrt_int (x:'N) :'N = ((^T or ^N) : (static member Sqr: ^T * ^N -> _) T, x)

Подробнее об этом здесь.

Answer 3

Да, это можно сделать. Взгляните на эту ветку hubFS.

В этом случае решение будет:

let inline retype (x:'a) : 'b = (# "" x : 'b #)
let inline sqrt_int (n:'a) = retype (sqrt (float n)) : 'a

Предостережение: нет проверки типов во время компиляции. Т.е. sqrt_int "blabla" компилируется нормально, но вы получите FormatException во время выполнения.

Answer 4

Вот еще один способ использования проверок типов во время выполнения...

let sqrt_int<'a> (x:'a) : 'a = // '
    match box x with
    | :? int as i -> downcast (i |> float |> sqrt |> int |> box)
    | :? int64 as i -> downcast (i |> float |> sqrt |> int64 |> box)
    | _ -> failwith "boo"

let a = sqrt_int 9
let b = sqrt_int 100L
let c = sqrt_int "foo" // boom

Answer 5

Не отнимать от уже предоставленных правильных ответов, но вы можете использовать ограничения типов в сопоставлении с образцом. Синтаксис:

| :? type ->

Или, если вы хотите совместить проверку типов и приведение типов:

| :? type as foo ->