Как я могу получить список дисков из командного файла?

Я пытаюсь получить список всех подключенных дисков для обновления системы и хотел бы получить эту информацию через командный файл. Как я могу это сделать?

Для бонусных баллов: Как я могу написать сценарий сопоставления этих дисков на новом сервере?

Источник

3 ответа

Решение

Список текущих отображений будет возвращен

net use

Передача будет работать так (для забавы1, давайте сделаем это в пакетном скрипте вместо VBScript):

@echo off

setlocal EnableDelayedExpansion

set letter=.
set uncpath=.
set colon=.

for /f "delims=" %%l in ('net use') do @(
  for /f "tokens=2" %%t in ("%%l") do @set letter=%%t
  for /f "tokens=3" %%t in ("%%l") do @set uncpath=%%t

  set colon=!letter:~1,1!

  if "!colon!" EQU ":" (
    echo if exist !letter! net use !letter! /delete
    echo net use !letter! !uncpath! /persistent:yes
  )
)

endlocal

вывод идет примерно так:

if exist M: net use M: /delete
net use M: \\someserver\someshare /persistent:yes
if exist N: net use N: /delete
net use N: \\otherserver\othershare /persistent:yes

Просто сохраните это в пакетном файле, и все готово.

1 На самом деле, "веселье" здесь не то слово.;-)

Источник

Чтобы отобразить подключенные диски

Net Use

Для сопоставления нового диска

Net Use G: \\Server\Path
Источник

Вы можете сделать это с помощью vbscript

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set colDrives = objFSO.Drives

For Each objDrive in colDrives
    Wscript.Echo "Drive letter: " & objDrive.DriveLetter
Next

И вы можете сопоставить сетевые диски с

Set objNetwork = CreateObject("WScript.Network") 
objNetwork.MapNetworkDrive "G:", "\\Server\Path"
Источник
Другие вопросы по тегам