Как получить значок и описание из расширения файла, используя Delphi?
По сути, у меня есть TcxGrid, в котором будут перечислены различные имена файлов, и я хотел бы дать дополнительную информацию, основанную на расширении файла, в частности, его описание (например, для.PDF это "Adobe Acrobat Document") и соответствующий значок.
Я заметил, что уже есть очень похожий вопрос, но он связан с C#, и я хотел бы что-то на основе Delphi.
Было бы неплохо предложить, где искать такую информацию, и если бы был класс, похожий на класс, упомянутый в посте C# выше (очевидно, в Delphi), это было бы здорово.
7 ответов
Спасибо Робу Кеннеди за то, что он указал мне направление ShGetFileInfo. Я тогда гуглил и нашел эти два примера - Delphi 3000, Torry's. Из этого я написал следующий класс, чтобы сделать то, что мне нужно.
Кроме того, как только я заканчивал, ответ Билла Миллера дал мне последнюю часть помощи, в которой я нуждался. Первоначально я передавал полные имена файлов в ShGetFileInfo, что в идеале не было тем, что я хотел. Твик, подсказавший прохождение "*.EXT", был великолепен.
Класс может выполнять больше работы, но он делает то, что мне нужно. Кажется, он обрабатывает расширения файлов, которые не связаны с деталями.
Наконец, в том, что я использую, я переключил его на использование TcxImageList вместо TImageList, так как у меня были проблемы с появлением черных границ на значках, потому что это было быстрое решение.
unit FileAssociationDetails;
{
Created : 2009-05-07
Description : Class to get file type description and icons.
* Extensions and Descriptions are held in a TStringLists.
* Icons are stored in a TImageList.
Assumption is all lists are in same order.
}
interface
uses Classes, Controls;
type
TFileAssociationDetails = class(TObject)
private
FImages : TImageList;
FExtensions : TStringList;
FDescriptions : TStringList;
public
constructor Create;
destructor Destroy; override;
procedure AddFile(FileName : string);
procedure AddExtension(Extension : string);
procedure Clear;
procedure GetFileIconsAndDescriptions;
property Images : TImageList read FImages;
property Extensions : TStringList read FExtensions;
property Descriptions : TStringList read FDescriptions;
end;
implementation
uses SysUtils, ShellAPI, Graphics, Windows;
{ TFileAssociationDetails }
constructor TFileAssociationDetails.Create;
begin
try
inherited;
FExtensions := TStringList.Create;
FExtensions.Sorted := true;
FDescriptions := TStringList.Create;
FImages := TImageList.Create(nil);
except
end;
end;
destructor TFileAssociationDetails.Destroy;
begin
try
FExtensions.Free;
FDescriptions.Free;
FImages.Free;
finally
inherited;
end;
end;
procedure TFileAssociationDetails.AddFile(FileName: string);
begin
AddExtension(ExtractFileExt(FileName));
end;
procedure TFileAssociationDetails.AddExtension(Extension : string);
begin
Extension := UpperCase(Extension);
if (Trim(Extension) <> '') and
(FExtensions.IndexOf(Extension) = -1) then
FExtensions.Add(Extension);
end;
procedure TFileAssociationDetails.Clear;
begin
FExtensions.Clear;
end;
procedure TFileAssociationDetails.GetFileIconsAndDescriptions;
var
Icon: TIcon;
iCount : integer;
Extension : string;
FileInfo : SHFILEINFO;
begin
FImages.Clear;
FDescriptions.Clear;
Icon := TIcon.Create;
try
// Loop through all stored extensions and retrieve relevant info
for iCount := 0 to FExtensions.Count - 1 do
begin
Extension := '*' + FExtensions.Strings[iCount];
// Get description type
SHGetFileInfo(PChar(Extension),
FILE_ATTRIBUTE_NORMAL,
FileInfo,
SizeOf(FileInfo),
SHGFI_TYPENAME or SHGFI_USEFILEATTRIBUTES
);
FDescriptions.Add(FileInfo.szTypeName);
// Get icon and copy into ImageList
SHGetFileInfo(PChar(Extension),
FILE_ATTRIBUTE_NORMAL,
FileInfo,
SizeOf(FileInfo),
SHGFI_ICON or SHGFI_SMALLICON or
SHGFI_SYSICONINDEX or SHGFI_USEFILEATTRIBUTES
);
Icon.Handle := FileInfo.hIcon;
FImages.AddIcon(Icon);
end;
finally
Icon.Free;
end;
end;
end.
Также вот пример тестового приложения, использующего его, оно очень простое, просто форма с TPageControl на нем. Мое фактическое использование было не для этого, а для Developer Express TcxImageComboxBox в TcxGrid.
unit Main;
{
Created : 2009-05-07
Description : Test app for TFileAssociationDetails.
}
interface
uses
Windows, Forms, FileAssociationDetails, Classes, Controls, ComCtrls;
type
TfmTest = class(TForm)
PageControl1: TPageControl;
procedure FormShow(Sender: TObject);
procedure FormClose(Sender: TObject; var Action: TCloseAction);
private
{ Private declarations }
FFileDetails : TFileAssociationDetails;
public
{ Public declarations }
end;
var
fmTest: TfmTest;
implementation
{$R *.dfm}
procedure TfmTest.FormShow(Sender: TObject);
var
iCount : integer;
NewTab : TTabSheet;
begin
FFileDetails := TFileAssociationDetails.Create;
FFileDetails.AddFile('C:\Documents and Settings\...\Test.XLS');
FFileDetails.AddExtension('.zip');
FFileDetails.AddExtension('.pdf');
FFileDetails.AddExtension('.pas');
FFileDetails.AddExtension('.XML');
FFileDetails.AddExtension('.poo');
FFileDetails.GetFileIconsAndDescriptions;
PageControl1.Images := FFileDetails.Images;
for iCount := 0 to FFileDetails.Descriptions.Count - 1 do
begin
NewTab := TTabSheet.Create(PageControl1);
NewTab.PageControl := PageControl1;
NewTab.Caption := FFileDetails.Descriptions.Strings[iCount];
NewTab.ImageIndex := iCount;
end;
end;
procedure TfmTest.FormClose(Sender: TObject; var Action: TCloseAction);
begin
PageControl1.Images := nil;
FFileDetails.Free;
end;
end.
Спасибо всем за ваши ответы!
function GetGenericFileType( AExtension: string ): string;
{ Get file type for an extension }
var
AInfo: TSHFileInfo;
begin
SHGetFileInfo( PChar( AExtension ), FILE_ATTRIBUTE_NORMAL, AInfo, SizeOf( AInfo ),
SHGFI_TYPENAME or SHGFI_USEFILEATTRIBUTES );
Result := AInfo.szTypeName;
end;
function GetGenericIconIndex( AExtension: string ): integer;
{ Get icon index for an extension type }
var
AInfo: TSHFileInfo;
begin
if SHGetFileInfo( PChar( AExtension ), FILE_ATTRIBUTE_NORMAL, AInfo, SizeOf( AInfo ),
SHGFI_SYSICONINDEX or SHGFI_SMALLICON or SHGFI_USEFILEATTRIBUTES ) <> 0 then
Result := AInfo.iIcon
else
Result := -1;
end;
function GetGenericFileIcon( AExtension: string ): TIcon;
{ Get icon for an extension }
var
AInfo: TSHFileInfo;
AIcon: TIcon;
begin
if SHGetFileInfo( PChar( AExtension ), FILE_ATTRIBUTE_NORMAL, AInfo, SizeOf( AInfo ),
SHGFI_SYSICONINDEX or SHGFI_SMALLICON or SHGFI_USEFILEATTRIBUTES ) <> 0 then
begin
AIcon := TIcon.Create;
try
AIcon.Handle := AInfo.hIcon;
Result := AIcon;
except
AIcon.Free;
raise;
end;
end
else
Result := nil;
end;
Вызов ShGetFileInfo, Он может рассказать вам описание ("имя типа" в словаре этой функции) и может дать вам дескриптор значка или дескриптор списка системных изображений, где находится значок, или путь к модулю, который содержит ресурс изображения. Эта функция может делать много разных вещей, поэтому обязательно внимательно прочитайте документацию.
MSDN говорит ShGetFileInfo "может быть медленным" и вызывает IExtractIcon интерфейс "более гибкая и эффективная" альтернатива. Но последовательность, которую он рекомендует, это использовать IShellFolder интерфейс, затем позвоните GetUIObjectOf чтобы получить файл IExtractIcon интерфейс, а затем позвоните GetIconLocation а также Extract на нем, чтобы получить ручку значка.
Насколько я знаю, это именно то, что ShGetFileInfo в любом случае, но это гораздо более громоздко, и после того, как вы все это сделаете, у вас все равно не будет описания типа файла. Придерживаться ShGetFileInfo пока скорость и эффективность не станут заметной проблемой.
uses ShellAPI;
var
AExtension: string;
AFileType: string;
AListItem: TListItem;
AFileInfo: TSHFileInfo;
begin
// get the extensions file icon
AExtension := ExtractFileExt( FileName );
if SHGetFileInfo( PChar( '*' + AExtension ), FILE_ATTRIBUTE_NORMAL, AFileInfo, SizeOf
( AFileInfo ), SHGFI_SYSICONINDEX or SHGFI_SMALLICON or SHGFI_USEFILEATTRIBUTES ) <> 0 then
AIndex := AFileInfo.iIcon
else
AIndex := -1;
AListItem.ImageIndex := AIndex;
// get extensions file info
if SHGetFileInfo( PChar( '*' + AExtension ), FILE_ATTRIBUTE_NORMAL, Info, SizeOf( Info ),
SHGFI_TYPENAME or SHGFI_USEFILEATTRIBUTES ) then
AFileType := AFileInfo.szTypeName;
end;
Не звучит беспечно, но Google - твой друг. Вот пара первых результатов для "значка, ассоциированного с Delphi":
http://www.delphi3000.com/articles/article_453.asp?SK=
http://www.jpgriffiths.com/tutorial/Snippets%5Cgetassociatedicon.html
Вот несколько хороших примеров использования ShGetFileInfo с bitwisemag.com:
Другой метод заключается в поиске расширения в реестре в разделе HKEY_CLASSES_ROOT, затем следуйте ключу в значении по умолчанию (если доступно), и его значением по умолчанию является описание. На этом втором уровне также можно открыть команды оболочки или распечатать тип файла и путь к значку по умолчанию.